Hello Imre, I would do something like this (where you might want to be careful with the additional trick "?_view=frameless" in order to get more interactivity, since it also needs more cloud credits). Rolf

Clear[f1, f2, q1, q2, \[Beta], \[Nu], m]; \[Nu] = 2.42; m = 5; 
f1[z_, \[Beta]_] := (1 - (1/5)*(\[Nu]*(1 - \[Beta]))*(1 - z))^5; 
f2[z_, \[Beta]_] := 1 - \[Nu]*\[Beta]*(1 - z); 
q1[z_, \[Beta]_, \[Rho]_] := f1[z, \[Beta]]/(\[Nu]*(1 - \[Rho])) + 1 - 1/(\[Nu]*(1 - \[Rho])); 
q2[z_, \[Beta]_, \[Rho]_] := f2[z, \[Beta]]/(\[Nu]*(1 - \[Rho])) + 1 - 1/(\[Nu]*(1 - \[Rho])); 
dyn = Manipulate[Plot[{y, q1[y, \[Beta], \[Rho]]*q2[y, \[Beta], \[Rho]]}, {y, 0, 1}, 
    BaseStyle -> {FontFamily -> "Helvetica", FontSize -> 16, 
      FontWeight -> "Plain"}], {\[Beta], 0., 100*0.0065}, 
   {\[Rho], 0, 1 - 1/\[Nu]}, SaveDefinitions -> True]
CloudDeploy[dyn, CloudObject["dynamic.nb?_view=frameless"], 
  Permissions -> {All -> {"Read", "Interact", "Evaluate"}}]

One option is to create a duplicate version of the notebook that will be for other users. In that notebook, you can delete the input cell (click on the cell bracket, then delete key), leaving only the output cell.

Programmatically, you can deploy just the output cell by doing something like this:

CloudDeploy[Notebook[{Cell[ToBoxes@Manipulate[Plot[Sin[k x],{x,-Pi,Pi}],{k,1,2}],"Output"]}], CloudObject["dyn.nb"], Permissions-> {All->{"Read","Interact"}}]

I did not know that I can delete the input without affecting the output.
That's the solution, thanks agai

Hello Chad, now it works without entering any userid.
I still wish that the dynamic code (Manipulate, DynamicModule, etc,) can not be seen.
I hide it (only the output can be seen) but it can be opened with double click on the cell right bracket.
I can not find how to avoid it with "Permissions", can it be avoided?

The 'Home' folder in the cloud interface is misleading. That folder is actually your root directory ($CloudRootDirectory). I suspect that your notebook can be found with this evaluation:

CloudObject["mynb.nb"]

You can get a list of the files in your current cloud directory (default is $CloudRootDirectory, and it can be changed with the SetCloudDirectory function) by evaluating

objs=CloudObjects[];
CloudObjectInformation /@ objs

You can edit the deployed notebook because you are its owner. The Wolfram Cloud has a number of settings that determine the allowed interactions of other users. See the Permissions documentation page for more details. Here, I just note a few of them: "Evaluate" would enable a user to do a shift-enter evaluation of a cell. "Interact" allows a user to change dynamic settings.

To update the permissions for your notebook, you evaluate something like this (either in a cloud notebook or a desktop Mathematica notebook):

SetPermissions[CloudObject[- your cloud object name or url-], {All->{"Evaluate", "Interact"}}]

Wolfram Language also has PermissionsGroups for a group of users, or you could have a list of usernames (instead of 'All') that would have these permissions.