Message Boards Message Boards

Don't fear divergencies: $\int_0^{\infty}\frac{\tanh^3(x)}{x^2}\,dx$ ?

GROUPS:

NOTE: the notebook with full content is attached at the end of the post.


On Mathoverflow, the question about a closed form for the integral $\int_0^{\infty}\frac{\tanh^3(x)}{x^2}\,dx$ was raised. Currently, Mathematica can't give a closed form answer for this integral.

Integrate[Tanh[x]^3/x^2, {x, 0, ∞}]

enter image description here

But we can easily get a numerical value.

num = NIntegrate[Tanh[x]^3/x^2, {x, 0, ∞},  
WorkingPrecision -> 100, PrecisionGoal -> 30] // N[#, 30] &

1.15478531332317626405907045194

How could one fine a closed form result? With Integrate, Sum, SeriesCoefficient, ... we have a lot of tools at our hands to do some experimental mathematics. A simple manual change of variables does not help.

Integrate[y^3/(ArcTanh[y]^2)  Dt[ArcTanh[y], y], {y, 0, 1}]

enter image description here

The next typical trick is expanding the integrand in a series and integrating term by term:

TrigToExp[Tanh[x]^3]

enter image description here

SeriesCoefficient[% /. {Exp[-x] -> g, Exp[x] -> 1/g}, {g, 0, n}] // 
 FullSimplify[#, n ∈ Integers] &

enter image description here

The resulting integrals do diverge:

Integrate[Exp[-n x]/x^2 , {x, 0, ∞}]

enter image description here

We can make the integral convergent by adding a factor. For the case $α=0$ that we need, the integral diverges:

Integrate[Exp[-n x]/x^2 x^α , {x, 0, ∞}]

enter image description here

And the sum can be done in closed form for general $α$:

Sum[n^(1 - α) Gamma[-1 + α] Cos[(n π)/2] (2 + n^2), {n, ∞}]

enter image description here

Expanding the result around $α=0$ gives a finite leading term:

Series[%, {α, 0, 1}]

enter image description here

And indeed this is the result we were looking for:

N[(-1 - (4 Log[2])/15 + 12 Log[Glaisher] - 120 Derivative[1][Zeta][-3]), 30]

1.15478531332317626405907045194

Alternatively, we can split of the divergent point from the integral:

Integrate[Exp[-n x]/x^2, {x, ε, ∞}]

enter image description here

The leading terms are:

Series[(E^(-n ε)/ε - n Gamma[0, n ε]), {ε, 0, 2}, Assumptions -> ε > 0]

enter image description here

The n term does give no sum contribution:

Sum[n Cos[(n π)/2] (2 + n^2), {n, ∞}, Regularization -> "Dirichlet"]

0

And the $n \ln(n)$ term gives the same result as above:

Sum[n Log [n] Cos[(n π)/2] (2 + n^2) n^α, {n, ∞}]

enter image description here

Series[%, {\[Alpha], 0, 1}]

enter image description here

By conjecturing the constants involved in the integral, we could have used FindIntegerNullVector to get a conjecture for a closed form:

FindIntegerNullVector[{1.15478531332317626405907045194,1, 
Log[2], EulerGamma, Log[Glaisher], Derivative[1][Zeta][-3]}]

{-15, -15, -4, 0, 180, -1800}

Attachments:
POSTED BY: Michael Trott
Answer
25 days ago

enter image description here - Congratulations! This post is now a Staff Pick as distinguished on your profile! Thank you, keep it coming!

POSTED BY: Moderation Team
Answer
25 days ago

Dear Michael Trott,

Since 2009 I've been greatly wondering if my integral could possibly have a closed form that could be found in like manor as yours. Its DirichletEta^(m)[m] derivatives of its sum analog extensively use the same terms as the result you found: zeta^(n)[x], EulerGamma, Log[Glaishier], and I think others. Some of the constants can be seen from:

(*In[121]:= *)
EulerGamma Log[2] - Log[2]^2/2 - 
 Limit[D[DirichletEta[u], {u, 1}], u -> 1]

(*Out[121]= 0, and*)

(*In[119]:=*)FullSimplify[(-(1/12))*(Pi^2*Log[2]^2 - 
     2*Pi^2*Log[
       2]*(EulerGamma + Log[2] - 12*Log[Glaisher] + Log[Pi]) - 
          6*Derivative[2][Zeta][2]) - (D[DirichletEta[u], {u, 2}] /. 
    u -> 2)]

(*Out[119]= 0 *)

. Can you give it a spin for me and see if you can come up with a closed form? Of course I understand that there is a good probability that none exists, but since I already spent 8 years looking, no sense in giving up now! The integral is

  Limit[Integrate[Exp[x I Pi] x^(1/x), {x, 1, 2 n}],n->Infinity].

The sum analog mentioned, at the end of 6.11., by Steven R Finch here, is Sum[(-1)^k (k^(1/k)-1),{n,1,Infinity}] equals

    Limit[D[DirichletEta[u], {u, 1}], u -> 1] + Sum[(-1)^(m + 1) (D[DirichletEta[u], {u, m}] /. u -> m)/m!, {m, 2, Infinity}]

as found by the late, Chief Scientist and Apple's Chief Cryptographer Richard Crandall, at 7.5, here.

If it's any help, Richard Mathar numerically evaluated the Integral here.

P.S. Your constant was the motivation behind my invention here and here.

You have no Idea how important this is to me!

POSTED BY: Marvin Ray Burns
Answer
25 days ago

Group Abstract Group Abstract