Message Boards Message Boards

GROUPS:

Plot z as a function of "a"?

Posted 6 months ago
510 Views
|
6 Replies
|
5 Total Likes
|

How can I plot z as a function of "a"?

z = Table[NIntegrate[Sin[a + b x], {x, -10, 10}], {b, 0, 5, 0.5}, {a, 0, 5,  0.5}];
ListPlot[z, Joined -> True, PlotRange -> All]

enter image description here

6 Replies
u = Integrate[Sin[a + b*x], {x, -10, 10}];
{Plot3D[u, {a, 0., 5}, {b, 0.0001, 5}, PlotRange -> All, Mesh -> None,
   ColorFunction -> Hue, AxesLabel -> {"a", "b", ""}], 
 Plot[u /. b -> 1, {a, 0, 5}, AxesLabel -> Automatic]}

fig

Posted 6 months ago

Hey. Thank you a lot. Why did you replace NIntegrate with Integratre?

In[1]:= u = Integrate[Sin[a + b*x], {x, -10, 10}]  
Out[1]= (2 Sin[a] Sin[10 b])/b
Posted 6 months ago

Yes, but this function is just a simple example. My original function is more complicated, so I need NIntegrate.

OK! Let me take a look at the general cases on this particular example:

u = Flatten[
  Table[{a, b, NIntegrate[Sin[x^a - x^b], {x, 1, 2}]}, {a, 1, 
    2, .1}, {b, 3, 4, .1}], 1];
ListPlot3D[u, AxesLabel -> {"a", "b", ""}, Mesh -> None, 
 ColorFunction -> Hue]

fig2

Fu = Interpolation[u]
{Plot[Fu[a, 3.5], {a, 1, 2}, AxesLabel -> Automatic], 
 Plot3D[Fu[a, b], {a, 1, 2}, {b, 3, 4}, Mesh -> None, 
  ColorFunction -> Hue]}

fig3

Posted 6 months ago

Thank you again. This is exactly equal to

F[a_?NumericQ, b_?NumericQ] := NIntegrate[Sin[x^a - x^b], {x, 1, 2}]
Plot[F[y, 3.5], {y, 1, 2}]

enter image description here

Why that?

Reply to this discussion
Community posts can be styled and formatted using the Markdown syntax.
Reply Preview
Attachments
Remove
or Discard

Group Abstract Group Abstract