Message Boards Message Boards

2016 North Korea Nuclear Test: How does it compare?

The quick piece of international intelligence from Wolfram Alpha is quite remarkable. The position and time of these earthquakes matches that of North Korea nuclear tests. The most recent earthquake took place on Wednesday and it had a magnitude of 5.1. The nuclear test from 2013 had a very similar effect and it was located at the same place:

EarthquakeData[Entity["Country", "NorthKorea"], 5, {{2013, 1, 1}, {2016, 1, 7}}]

2013 and 2016 tests

In this post I'll make some data visualizations using the Wolfram Language to put that recent nuclear explosion into context. Let's start by taking all the positions and explosive yields of all previous nuclear explosions available in NuclearExplosionData:

explosions = NuclearExplosionData[All, {"Position", "Yield"}]

The explosions can be mapped with GeoGraphics:

GeoGraphics[{GeoMarker[EarthquakeData[Entity["Earthquake","us10004bnm"],"Position"],Entity["Icon","NuclearTestSite"],"Color"->Black],
Red,Opacity[0.2],
Map[GeoDisk[First[#],Quantity[5Log[QuantityMagnitude[Last[#]]],"mi"]]&,
Select[explosions,!MissingQ[Last[#]]&]]},
GeoBackground->"StreetMapNoLabels",GeoRange->{{-60,80},{-30,500}},GeoProjection->"Mercator",Frame->True,
PlotLabel->Style["Map of Nuclear Explosions Since 1945 (North Korean 2016 nuclear test highlighted in black)",16],
ImageSize->1000]

Map of Nuclear Explosions Since 1945

The nature of the bomb is still subject of controversy. North Korea does not publicize the depth of its tests but the yield of that last explosion has an estimated energy of 6 kilotons of TNT. When compared with past nuclear explosions, it is clear that this wasn't a big bomb:

UnitConvert[Quantity[6,"KilotonsOfTNT"],"J"]

2.5104*10^13 J

Framed[ListLogLinearPlot[NuclearExplosionData[All,{"Yield","HeightOfBurst"}],
PlotStyle->{Red,Opacity[.5],PointSize[.01]},
GridLines->Automatic,GridLinesStyle->Dashed,
Ticks->{{{UnitConvert[Quantity[6,"KilotonsOfTNT"],"J"],"2.5104*10^13J\n6 kilotons of TNT\nNorth Korea Nuclear Test",{0,.4},Thick},{Quantity[10000000000,"Joules"],"10^10 J"},{Quantity[1000000000000,"Joules"],"10^12 J"},{Quantity[10000000000000000,"Joules"],"10^16 J"}},{Quantity[-3000,"Meters"],Quantity[2000,"Meters"]}},
AxesStyle->Directive[Black,FontSize->13],AxesLabel->{"yield (J)","HOB (m)"},
PlotLabel->Style["Nuclear tests: height/depth of burst (HOB) vs. yield",16],
LabelStyle->Directive[Bold,Black],ImageSize->600],FrameStyle->Thick,RoundingRadius->25]

HOB vs Yield

If North Korea claims of successfully testing a hydrogen bomb are true, then the explosion was produced by a really small H-bomb. But the effects of detonating such a bomb in a city would be devastating. The prediction provided by NUKEMAP of the thermal radiation radius (3rd degree burns) for a 6 kilotons bomb is more than 1 km. This is how it would look like if detonated in Manhattan:

6 kiloton bomb in Manhattan

Background sources and references of NuclearExplosionData come from Johnston, W.R. “Database of nuclear tests, United States.” Johnstons Archive. 2008. »

POSTED BY: Bernat Espigulé
Reply to this discussion
Community posts can be styled and formatted using the Markdown syntax.
Reply Preview
Attachments
Remove
or Discard

Group Abstract Group Abstract