Back Away

These are the vertices of the alternated cubic honeycomb, a tiling of 3-space by tetrahedra and octahedra. The vertices are all moving away from the camera, but they also fade in or out as they enter or leave the bounding box.

Here's the code, which is too slow for a useful Manipulate, so I just give the code for building the table of frames and exporting the GIF:

dots = Module[
   {n = 12, o = 0.5, points, edges, fadeinpoints, fadeoutpoints,
    cols = RGBColor /@ {"#122D42", "#CBF9DA"}},
   points = 
    Select[Flatten[
      Table[{i, j, k}, {i, -n, n - 2}, {j, -n, n}, {k, -n, n}], 2], 
     EvenQ[Total[#]] &];
   fadeinpoints = 
    Select[Flatten[
      Table[{i, j, k}, {i, -n - 2, -n - 1}, {j, -n, n}, {k, -n, n}], 2], 
      EvenQ[Total[#]] &];
   fadeoutpoints = 
    Select[Flatten[
      Table[{i, j, k}, {i, n - 1, n}, {j, -n, n}, {k, -n, n}], 2], 
     EvenQ[Total[#]] &];
   ParallelTable[
      Graphics3D[{PointSize[.012], Opacity[o], cols[[1]], 
        Point[{d, 0, 0} + #] & /@ points, Opacity[o*d/2], 
        Point[{d, 0, 0} + #] & /@ fadeinpoints, Opacity[o (1 - d/2)], 
        Point[{d, 0, 0} + #] & /@ fadeoutpoints},
       Boxed -> False, ViewPoint -> {-2, 0, 0}, 
       ViewVertical -> {0, 0, 1}, ViewAngle -> ?/7, 
       PlotRange -> n + 2, ImageSize -> 540, SphericalRegion -> True, 
       Background -> Lighter[cols[[-1]], .7]],
      {d, 0., 2 - #, #}] &[2/10]
   ];

Export[NotebookDirectory[] <> "dots.gif", dots, "DisplayDurations" -> {1/24}]