If you want to calculate the constraints for the angles you can do it this way:

cond1 = Sqrt[x^2 + y^2 + z^2] <= 1 && z > 0;
cond2 = Sqrt[x^2 + y^2 + z^2] <= 1 && x > 0 && z > 0;

If you replace x,y,z with there representation in spherical coordinates, you get conditions for r and some trigonometric expressions:

cond3 = Simplify[
  cond1 /. Thread[{x, y, z} -> 
     CoordinateTransform[
      "Spherical" -> "Cartesian", {r, \[Theta], \[Phi]}]], r > 0]

"Reduce" can be used to derive finally constraints for the angles themself:

Reduce[cond3 && 0 <= \[Theta] <= \[Pi], \[Theta]]

cond4 = Simplify[
  cond2 /. Thread[{x, y, z} -> 
     CoordinateTransform[
      "Spherical" -> "Cartesian", {r, \[Theta], \[Phi]}]], r > 0]

Reduce[cond4 && 0 <= \[Theta] <= \[Pi] && 
  0 <= \[Phi] <= 2 \[Pi], {\[Phi], \[Theta]}]

Using region functionalities you can easily compute the volumes and display the defined regions:

 reg1 = ImplicitRegion[cond1, {x, y, z}];
 reg2 = ImplicitRegion[cond2, {x, y, z}];

RegionMeasure can be used to compute the volume:

 {RegionMeasure[reg1, 3], RegionMeasure[reg2, 3]}

Region will display the defined regions:

  {Region[reg1], Region[reg2]}

Help: ref/ClipPlanesStyle works by planes, graphics 3D has other tricks too (include ones that operate on invisible object having textures on their surface)

Help ref/RegionFunction applies to plotting and exclusions

the best way to do what your thinking depends on what shapes and exclusions you ultimately want (be careful of what you ask for)

primarily, i would suggest reviewing Plot and Graphics3D to see which of the many features that do clipping, exclusions, and other things have the ultimate effect you seek

for example, if i said "use clipping" i would have no idea if "all of your specifications" might be possible