Ability to see direction of Parametric Curves when plotted?

Questions
,
1

Hello, all!

I have not been able to find any documentation on the docs for a way to see on the direction a single parameter curve has on a certain interval. I have seen many plots that were created using mathematica which led me to believe that I can - at the very least - determine the direction by seeing labeled points, let’s say ‘t’, on my plot. My question is, is there a known method that I may use to determine the direction of a parametric curve?

I have been using ParametricPlot[]. The docs for it hasn’t provided any hint of this type of feature. Where should I look to read up on a feature similar to what I have described wanting?

2

From this site:

  eqs = {x == 1 - t^2, y == -2 t - 2};
  eq2 = {x, y} /. (And @@ eqs // ToRules)
  ParametricPlot[eq2, {t, -5, 5}, MeshStyle -> Red, Mesh -> True, Epilog -> Arrow@Partition[Table[eq2, {t, -5, 5, 0.5}], 2]]

wwww.png
wwww.png393×308 7.1 KB

Or, from:

   ParametricPlot[eq2, {t, -5, 5}] /. Line[x_] :> Sequence[Arrowheads[Table[.05, {10}]], Arrow@Line[x]]

rrrr.png
rrrr.png381×300 3.41 KB

3

+1

Thanks, mate!

This is exactly what I have been looking for!

4

It should be an option to ParametricPlot[]. But here’s another easy workaround.

f[t_] := {Cos[t], Sin[t]}
Show[
 ParametricPlot[f[t], {t, 0, 3/5 Pi}], 
 Graphics[{Red, Arrowheads[.1], 
   Arrow[{f[3/5 Pi - .01], f[3/5 Pi]}, -.02]}]]
5

Thank you!

6

This is done with labels:

f[t_] := {Cos[t], Sin[t]}
ParametricPlot[f[t], {t, 0, 3/5 Pi},
 Epilog -> Table[{PointSize[Medium], Point[f[s]],
    Text[t == s, f[s],
     1.3 RotationMatrix[Pi/2] . Normalize[f'[s]]]},
   {s, Subdivide[0, 3/5 Pi, 5]}],
 PlotRangePadding -> Scaled[.15]]