Avoid discontinuities in visualization of supertoroidal surfaces?

Questions
, ,
1

Hello,
I am running the following line of code for Mathematica 10 to visualize superquadrics (supertoroid):

Manipulate[
 ParametricPlot3D[{a1*(a4 + Sign[Cos[u]]*Abs[Cos[u]]^eps1)*
    Sign[Cos[t]]*Abs[Cos[t]]^eps2, 
   a2*(a4 + Sign[Cos[u]]*Abs[Cos[u]]^eps1)*Sign[Sin[t]]*
    Abs[Sin[t]]^eps2, a3*Sign[Sin[u]]*Abs[Sin[u]]^eps1}, {t, -Pi, 
   Pi}, {u, -Pi, Pi}, MaxRecursion -> 5, ViewPoint -> {2, 2, 2}, 
  PlotStyle -> Lighter[Red, op]],
 {{op, 1, "Lightness"}, 0, 1, Appearance -> "Labeled"},
 {{a1, 1, "Parameter a1"}, 0, 5, 
  Appearance -> "Labeled"}, {{a2, 1, "Parameter a2"}, 0, 5, 
  Appearance -> "Labeled"}, {{a3, 1, "Parameter a3"}, 0, 5, 
  Appearance -> "Labeled"}, {{a4, 1, "Parameter a4"}, 0, 5, 
  Appearance -> "Labeled"}, {{eps1, 1, "Parameter eps1"}, 0, 5, 
  Appearance -> "Labeled"}, {{eps2, 1, "Parameter eps2"}, 0, 5, 
  Appearance -> "Labeled"}]

Supertoroids.png
Supertoroids.png360×301 47.3 KB

Unfortunately, the image has several discontinuities (see Figure) and I do not know how to fix it. These discontinuities are more significant if parameters eps1 and eps2 are smaller (i.e. 0.25). Could anyone help with that?
Thank you,

Wawosz

2

Try eliminating the exclusions: Exclusions->None

Manipulate[
 ParametricPlot3D[{a1*(a4 + Sign[Cos[u]]*Abs[Cos[u]]^eps1)*
    Sign[Cos[t]]*Abs[Cos[t]]^eps2, 
   a2*(a4 + Sign[Cos[u]]*Abs[Cos[u]]^eps1)*Sign[Sin[t]]*
    Abs[Sin[t]]^eps2, a3*Sign[Sin[u]]*Abs[Sin[u]]^eps1}, {t, -Pi, 
   Pi}, {u, -Pi, Pi}, Exclusions -> None, MaxRecursion -> 5, 
  ViewPoint -> {2, 2, 2}, 
  PlotStyle -> Lighter[Red, op]], {{op, 1, "Lightness"}, 0, 1, 
  Appearance -> "Labeled"}, {{a1, 1, "Parameter a1"}, 0, 5, 
  Appearance -> "Labeled"}, {{a2, 1, "Parameter a2"}, 0, 5, 
  Appearance -> "Labeled"}, {{a3, 1, "Parameter a3"}, 0, 5, 
  Appearance -> "Labeled"}, {{a4, 1, "Parameter a4"}, 0, 5, 
  Appearance -> "Labeled"}, {{eps1, 1, "Parameter eps1"}, 0, 5, 
  Appearance -> "Labeled"}, {{eps2, 1, "Parameter eps2"}, 0, 5, 
  Appearance -> "Labeled"}]

6453Untitled-1.png
6453Untitled-1.png540×448 71.8 KB

3

Try adding the Exclusions -> None option to ParametricPlot3D.

4

Thank you, Erik. It worked!

5

Thank you, Gianluca.