[?] Calculate a double Integrate over an ellipse region?

Questions
,
1

Hello! I have a simple question? How do I double integrate a function over an Elipsis Region? Something similar to a Circle Region, like

In_85.png

Thanks in advance.

2

Hello

 Integrate[1, {x, y} \[Element] Circle[{0, 0}, {a, b}]]

but Mathematica 11.3 gives unevaluated answer:

33333.png

it should be: 4 a E\left(1-\frac{b^2}{a^2}\right)

You can use:

ArcLength[Circle[{0, 0}, {a, b}]]
(* 4 b EllipticE[1 - a^2/b^2] *)

Regards,MI

3

Works in my copy of 11.3

In[6]:= Assuming[a > 0 && b > 0, Integrate[1, {x, y} \[Element] Circle[{0, 0}, {a, b}]]]

Out[6]= 2 (b EllipticE[1 - a^2/b^2] + a EllipticE[1 - b^2/a^2])
4

Well, these might work, too:

Integrate[1, {x, y} \[Element] RegionBoundary[Ellipsoid[{0, 0}, {r1, r2}]], Assumptions -> {r1 > 0, r2 > 0}]

Screenshot2018-03-1220.26.40.png
Screenshot2018-03-1220.26.40.png732Ă—126 5.06 KB

This gives the same answer (on 11.3)

Integrate[1, {x, y} \[Element] Circle[{0, 0}, {r1, r2}], Assumptions -> {r1 > 0, r2 > 0}]

Cheers,

Marco

5

Yes with Assumptions work in my copy to.

Thanks.

6

It also works without Assumptions, but returns (understandably) a much larger result and takes quite a bit of time.
It might return unevaluated on a slower machine, I suppose.

7

Indeed it does:

Screenshot2018-03-1220.39.37.png
Screenshot2018-03-1220.39.37.png1524Ă—1348 91.9 KB

Sorry for the late posting, but apparently every contribution to any thread only shows up much later for me than for many others on the Community.

Cheers,

Marco

8

Thanks for the response! But, I have another doubt, I was expecting a number as a result (like a volume). What Do I Have to do with EllipticE?

9

You will have to provide values for the two radii:

Integrate[1, {x, y} \[Element] Circle[{0, 0}, {1, 2}]]
(*8 EllipticE[3/4]*)

and

NIntegrate[1, {x, y} \[Element] Circle[{0, 0}, {1, 2}]]
(*9.68845*)

Cheers,

Marco

PS: Note that this is the circumference not the “volume” as you suggest in your question. The area is easy:

Integrate[1, {x, y} \[Element] Disk[{0, 0}, {r1, r2}], Assumptions -> {r1 > 0, r2 > 0}]
(*\[Pi] r1 r2*)

and

NIntegrate[1, {x, y} \[Element] Disk[{0, 0}, {1, 2}]]
(*6.28319*)

The volume of an Ellipsoid would be

Integrate[1, {x, y, z} \[Element] Ellipsoid[{0, 0, 0}, {r1, r2, r3}], Assumptions -> {r1 > 0, r2 > 0, r3 > 0}]
(*4/3 \[Pi] r1 r2 r3*)

or e.g.

NIntegrate[1, {x, y, z} \[Element] Ellipsoid[{0, 0, 0}, {1, 2, 3}]]
(*25.1327*)
10

I don’t know if I undestood correctly. How would you calculate this, for example?

download.png

11

Hi,

this forum is not actually suppose to solve homework problems, but

Integrate[1, {x, y} \[Element] ImplicitRegion[x^2 + y^2 - 2 y <= 0, {x, y}]]
(*\[Pi]*)

So, the answer in this case is Pi.

Cheers,

Marco

PS: Also, could you change the title of this thread to “Double Integral”? Doube has a different meaning…