Evaluation of solving simultaneous differential equations doesn't end

Questions
, ,
1

My code in Mathematica:

eqn1 = (M - ((\[Alpha]^2)/\[Beta])) u''[x] + (e - f)*
     P''[x] + (\[Alpha]/\[Beta])*\[Mu]'[x] == 0;

eqn2 = (e - f)*u''[x] + b*P''[x] - a*P[x] + (1/q)*\[Mu]'[x] == 0;

eqn3 = \[Epsilon]r*\[Mu]''[x] + (1/(\[Lambda]^2))*\[Mu][
      x] - (1/(\[Lambda]^2))*(\[Mu]hat + \[Alpha]*u'[x]) == 0;

DSolve[{eqn1, eqn2, eqn3}, {u[x], P[x], \[Mu][x]}, x]

I ran this for almost a day but didnt give any results, also there are no errors. I am not sure what is wrong? Is the way I have written the equations wrong or are these differential equations unsolvable? Any help would be appreciated.
Thanks

2

See attached file.

Regards…

Equations.nb (8.42 MB)

3

The problem seems to be too many free parameters. You can solve one equation at a time:

sol1 = DSolve[eqn1, u, x][[1]]
sol2 = DSolve[Simplify[eqn2 /. sol1], P, x]
sol3 = DSolve[Simplify[eqn3 /. sol1 /. sol2], \[Mu][x], x]
4

Thanks. But there seem to be Inactive[Integrate] functions. Have any suggestions how to combat those?

5

You combat Inactive[Integrate] with Activate and backsubstitution:

solU0[x_] = DSolveValue[eqn1, u[x], x]
solP0[x_] = 
 DSolveValue[Simplify[eqn2 /. u -> Function[x, Evaluate[solU0[x]]]],
   P[x], x] // Simplify
solMu[x_] = 
 DSolveValue[
    Simplify[
     eqn3 /. u -> Function[x, Evaluate[solU0[x]]] /. 
      P -> Function[x, Evaluate[solP0[x]]]],
    \[Mu][x], x] // Activate // Simplify
FreeQ[solMu[x], Integrate]
solP[x_] = 
 Simplify[solP0[x] /. \[Mu] -> Function[x, Evaluate[solMu[x]]]] // 
  Activate
FreeQ[solP[x], Integrate]
solU[x_] = 
 Simplify[
   solP0[x] /. \[Mu] -> Function[x, Evaluate[solMu[x]]] /. 
    P -> Function[x, Evaluate[solP0[x]]]] // Activate
FreeQ[solU[x], Integrate]

Beware that you get very large expressions.