Get the Piechart Labeling style found in a documentation example, MMA 11.3?

Questions
, , ,
1

Hi there,

Regarding to Version 11.3 “ref/PieChart” page → Applications (15)-> the third example.

Before evaluation:

2268Sketch.jpg
2268Sketch.jpg1528×1132 211 KB

After evaluation: (tiny pie chart as label )

Sketch2.jpg
Sketch2.jpg1407×962 128 KB

Question: How to revert to the style in the first picture?

2

Sample Code:

data = {13, 17, 22, 21, 20, 0.6, 1.3, 2.4, 0.8, 1.9};
largeData = Take[data, 5];
smallData = Drop[data, 5];

smallPie = 
 PieChart[smallData, ImageSize -> Medium, 
  LabelingFunction -> "RadialCenter", 
  ChartLabels -> Placed[CharacterRange["F", "Z"], "RadialOutside"]]

PieChart[Append[largeData, Total[smallData]], ImageSize -> Medium, 
 LabelingFunction -> "RadialCenter", 
 ChartLabels -> 
  Placed[Append[CharacterRange["A", "E"], Magnify[smallPie, 0.4]], 
   "RadialCallout"], PlotRange -> All]
3

Add LabelingSize → Full to the second PieChart:

data = {13, 17, 22, 21, 20, 0.6, 1.3, 2.4, 0.8, 1.9};
largeData = Take[data, 5];
smallData = Drop[data, 5];

smallPie = 
 PieChart[smallData, ImageSize -> Tiny, 
  LabelingFunction -> "RadialCenter", 
  ChartLabels -> Placed[CharacterRange["F", "Z"], "RadialOutside"]]

PieChart[Append[largeData, Total[smallData]], ImageSize -> Medium, 
 LabelingFunction -> "RadialCenter", 
 ChartLabels -> 
  Placed[Append[CharacterRange["A", "E"], smallPie], "RadialCallout"],
  PlotRange -> All, LabelingSize -> Full]