[GIF] Vanishing Point (Conformal image of a vertical grid)

Staff Picks
, , , ,
1

grid3.gif

Vanishing Point

This is essentially the same setup as :eyes: : the map f(z) = \frac{-4i}{z} maps the infinite strip \{z \in \mathbb{C} : 1 \leq \operatorname{Re}(z) \leq 2\} to the region between the two circles \{z \in \mathbb{C}: |z+i| = 1\} and \{z \in \mathbb{C}: |z+2i|=2\}, so the square grid in the strip gets mapped to a right-angled grid in the region between circles.

Code for a (very slow) Manipulate (see this comment for the process of exporting to GIF):

With[{r = 20, d = 11, 
  cols = RGBColor /@ {"#00a8cc", "#ffa41b", "#000839"}},
 Manipulate[
  Graphics[{EdgeForm[None], 
    Table[{Blend[cols[[;; 2]], (i - 1)/(Length[#] - 1)], 
        Polygon[Join[#[[i, 1]], Reverse[#[[i, 2]]]]]},
       {i, 1, Length[#]}]
      &@Partition[Table[ReIm[(-4 I)/(x + I t)], {x, 1., 2, 1/d}, {t, -50, 50, .01}], 2],
    cols[[-1]],
    Polygon[Join[#[[1]], Reverse[#[[2]]]]] & /@ 
     Partition[Table[ReIm[(-4 I)/(1 + t + I (y - u))], {y, Join[Table[s, {s, -r, r, 1./d}]]}, {t, -.01, 1, .01}], 2]},
   ImageSize -> 540, PlotRange -> {{-2.6, 2.6}, {-4.6, .6}}, 
   Axes -> None, Background -> cols[[-1]]],
  {u, 0, 2/d}]
 ]
10 Likes
[GIF] Rise (Conformal image of parallel lines)
2

news-congrads-kkluyshnik-02-04-19.jpg – you have earned Featured Contributor Badge 2015-11-02_10-07-11.png

Your exceptional post has been selected for our editorial column Staff Picks http://wolfr.am/StaffPicks and Your Profile is now distinguished by a Featured Contributor Badge and is displayed on the Featured Contributor Board. Thank you, keep it coming, and consider contributing to the The Notebook Archive!

3

Thanks for making this nice animation and giving us permission to use it in the product. In the just released Wolfram Language 14.3, we added support for importing static and animated AVIF files and your creation is added as an animation sample. See here:

Import["ExampleData/animation.avif", "AnimatedImage"]

animation.png

1 Like