# Halving half a disk

**URL:** <https://community.wolfram.com/t/halving-half-a-disk/927>\
**Category:** Questions\
**Tags:** mathematica, geometry\
**Created:** [November 21, 2013, 4:44am UTC](https://community.wolfram.com/t/halving-half-a-disk/927 "2013-11-21T04:44:19Z")\
**Posts on this page:** 7\
**Page:** 1

<div class="post-metadata">

**Author:** ![howardwilk](https://avatars.discourse-cdn.com/v4/letter/h/8baadc/32.png) [@howardwilk](https://community.wolfram.com/u/howardwilk)\
**Post date:** [November 21, 2013, 4:44am UTC](https://community.wolfram.com/t/halving-half-a-disk/927/1 "2013-11-21T04:44:19Z")

</div>

I want (for starters) to cut half a disk (which I think is the same thing as a “semicircular lamina”) into two pieces of the same area, with a cut parallel to the straight (“diametrical”) side of the half disk. (In all the following, radius is 1.) At first I applied the formula for the area enclosed by a chord at the Mathworld “chord” page, area = ArcCos-r Sqrt[1-r squared], where r is the distance from the center of the circle to the chord, to try to get an area of Pi/4. I couldn’t solve it, and my Mathematica couldn’t solve it, but by trial-and-error I got an r of around 0.4040 (I don’t need a mathematical solution; a numerical approximation will do). Then I saw there’s a Mathworld “semicircle” page, where the “geometric centroid of the semicircular lamina” (which I think is another way of describing what I’m looking for) is given as 4/(3Pi), which is about 0.4244. So either one or both pages is wrong, or what is of course much more likely, I’m missing something.

I’m calling it a night so I won’t be rejoining this discussion until tomorrow.

---

<div class="post-metadata">

**Author:** ![iliang](https://yyz1.discourse-cdn.com/wolfram/user_avatar/community.wolfram.com/iliang/32/11263_2.png) [@iliang](https://community.wolfram.com/u/iliang)\
**Post date:** [November 21, 2013, 6:07am UTC](https://community.wolfram.com/t/halving-half-a-disk/927/2 "2013-11-21T06:07:00Z")

</div>

The equation can be solved numerically to any desired precision with FindRoot, for example

```auto
In[2]:= FindRoot[ArcCos[r] - r Sqrt[1 - r^2] - Pi/4, {r, 0}, WorkingPrecision -> 20]

Out[2]= {r -> 0.40397275329951720932}

```

As for the discrepancy, this is because the centroid does not have the sought area-bisection property. To see the difference, consider for example a simple isosceles triangle. It is easy to check that the centroid is situated at 1/3 of the height, however the half-area line is at 1-1/Sqrt[2] of the height, which is lower than the centroid.

 ![ScreenShot2013-11-20at11.58.40PM.png](https://global.discourse-cdn.com/wolfram/original/2X/1/1dd1381b71e863010fc08da48f2dc6284ec6d942.png)

---

<div class="post-metadata">

**Author:** ![shenghuiy](https://yyz1.discourse-cdn.com/wolfram/user_avatar/community.wolfram.com/shenghuiy/32/36073_2.png) [@shenghuiy](https://community.wolfram.com/u/shenghuiy)\
**Post date:** [November 21, 2013, 8:15am UTC](https://community.wolfram.com/t/halving-half-a-disk/927/3 "2013-11-21T08:15:53Z")

</div>

Suppose the lamina is not exactly half disk. We can compute this extended problem easily with Mathematica.

 ![lamina.png](https://global.discourse-cdn.com/wolfram/original/3X/c/b/cbc6181b330d3313a78d98b92bdab135ec8d66ce.png)

Particulary, we are looking for the line P3\_P4 that cuts the lamina into two pieces of same area. So the area above p3\_p4 is basically that the area of Disk P3\_P0\_P4 minus the area of the blue triangle. The entire area of the lamina is that the area of Disk P0\_P1\_P3\_P4\_P2 plus the area of the red triangle. Call the obtuse angle of the red triangle: “phi”; the obtuse angle of the blue triangle : “theta”, we have

```auto
r=Sqrt[(1/2)^2+y0^2];
\[Phi]=2*ArcTan[1/(2*y0)];
s=(2\[Pi]-\[Phi])/2*r^2+1/2*r^2*Sin[\[Phi]];
res={r,\[Phi],\[Theta]/.FindRoot[r^2/2*\[Theta]-Sin[\[Theta]]/2*r^2==s/2,{\[Theta],\[Pi]/2}]}

```

where r is radius of the lamina, P0 = {0,y0} the center and the coordinate of p1 and p2 be {+/- 1/2 ,0} respectively . The above code is all you need to resolve this problem.  
I can merge the result and some extra graphics code to make a dynamic presentation:

![1598test.gif](https://global.discourse-cdn.com/wolfram/original/3X/b/d/bdc82d898ef3d7014ec60dd7eefbc9cc67512c31.gif)

where y0 is the distance between P0 and chord P1\_P2 and the ratio in the vertical axis is defined as 1 minus (height of blue triangle divides the radius of the circle). Certainly , when the center moves very far this ratio should be one, which means the diameter cuts the laminar into two identical parts approximately.

Copyable code:

```auto
Manipulate[
 {r, \[Phi], \[Theta]} = f[y0];
 p0 = {0, y0};
 p1 = {-1/2, 0};
 p2 = {1/2, 0};
 p3 = {-r*Sin[\[Theta]/2], y0 + r*Cos[\[Theta]/2]};
 p4 = {r*Sin[\[Theta]/2], y0 + r*Cos[\[Theta]/2]};
 tracker = {y0, 1 - Cos[f[y0][[3]]/2]};
 g = Graphics[
   {
    Circle[{0, y0}, 
     r, {-((\[Pi] - \[Phi])/2), (3*\[Pi] - \[Phi])/2}],
    {Red, Polygon[{p1, p2, {0, y0}}]},
    {Blue, PointSize[0.03], Point[{p1, p2}]},
    {Blue, PointSize[0.03], Point[{p3, p4}]},
    {Blue, Line[{p0, p3, p4, p0}]},
    Text["p0", p0 + {0, 0.1}],
    Text["p1", p1 - {0, 0.1}],
    Text["p2", p2 - {0, 0.1}],
    Text["p3", p3 - {0.1, 0}],
    Text["p4", p4 + {0.1, 0}]
    }];
 Plot[1 - Cos[f[x][[3]]/2], {x, 0.001, 1.3},
  PlotRange -> Full,
  AxesLabel -> {"y0", "ratio"}, LabelStyle -> Directive[13, Italic],
  Epilog -> {
    Inset[Style[g, Magnification -> 1.3], {0.9, 0.75 + y0/35}],
    {PointSize[0.02], Point[tracker]},
    {Dashed, Line[{{0, tracker[[2]]}, tracker, {tracker[[1]], 0}}]}
    }, ImageSize -> {500, 400}
  ]
 , {y0, 0.001, 1.3}, Initialization :> (
   f[y0_] := Module[{r, \[Phi], s, res},
     r = Sqrt[(1/2)^2 + y0^2];
     \[Phi] = 2*ArcTan[1/(2*y0)];
     s = (2 \[Pi] - \[Phi])/2*r^2 + 1/2*r^2*Sin[\[Phi]];
     res = {r, \[Phi], \[Theta] /. 
        FindRoot[
         r^2/2*\[Theta] - Sin[\[Theta]]/2*r^2 == s/
          2, {\[Theta], \[Pi]/2}]}
     ])]

```

---

<div class="post-metadata">

**Author:** ![howardwilk](https://avatars.discourse-cdn.com/v4/letter/h/8baadc/32.png) [@howardwilk](https://community.wolfram.com/u/howardwilk)\
**Post date:** [November 21, 2013, 3:44pm UTC](https://community.wolfram.com/t/halving-half-a-disk/927/4 "2013-11-21T15:44:17Z")

</div>

This info is great. Thank you both very much.

---

<div class="post-metadata">

**Author:** ![howardwilk](https://avatars.discourse-cdn.com/v4/letter/h/8baadc/32.png) [@howardwilk](https://community.wolfram.com/u/howardwilk)\
**Post date:** [November 21, 2013, 4:41pm UTC](https://community.wolfram.com/t/halving-half-a-disk/927/5 "2013-11-21T16:41:30Z")

</div>

I have a general question I’ll post also under a new discussion title, but in my case it happens to be related to the above question.

I have a book, _A Dictionary of Real Numbers_, by Borwein and Borwein. If you’re not familiar with it, it’s a list of numbers that are the result of a limited number of operations on a limited number of numbers. The numbers printed are eight digits after the decimal point, truncated, not rounded. I took the number I got by trial-and error, 0.403972, and looked up 403972, but it’s not in the book. But if for example in another problem I laboriously come up with -2.403441, I look in the book and find 40344144, and the book shows it came from 3Sqrt[2]/4-2Sqrt[3]. Of course this isn’t a mathematical proof that the number I calculated is equal to 3Sqrt[2]/4-2Sqrt[3], but it does suggest a direction I might want to go if I do try to prove it.

My question is, is there anything like this online?

---

<div class="post-metadata">

**Author:** ![bsimpson141421356](https://avatars.discourse-cdn.com/v4/letter/b/ac91a4/32.png) [@bsimpson141421356](https://community.wolfram.com/u/bsimpson141421356)\
**Post date:** [November 21, 2013, 4:56pm UTC](https://community.wolfram.com/t/halving-half-a-disk/927/6 "2013-11-21T16:56:41Z")

</div>

Google  
Inverse Symbolic Calculator  
but it does not include this particular constant.

[http://oldweb.cecm.sfu.ca/projects/ISC/ISCmain.html](http://oldweb.cecm.sfu.ca/projects/ISC/ISCmain.html)

---

<div class="post-metadata">

**Author:** ![howardwilk](https://avatars.discourse-cdn.com/v4/letter/h/8baadc/32.png) [@howardwilk](https://community.wolfram.com/u/howardwilk)\
**Post date:** [November 21, 2013, 10:47pm UTC](https://community.wolfram.com/t/halving-half-a-disk/927/7 "2013-11-21T22:47:20Z")

</div>

Thank you. This is useful, as is the answer I got when I posted under another discussion title, [RIES - Find Algebraic Equations, Given Their Solution at MROB](http://mrob.com/pub/ries/index.html)