How do I create a map with Germany and Turkey Highlighted

[esleesma (Eileen Sleesman)]

All I want is to create a map on mathematica online that I can use in a powerpoint presentation that shows where Germany and Turkey are. I cannot seem to get a correct output. Does anyone know how to do this?

[dreiss (David Reiss)]

Here is a start. You can tweak it with various Options to GeoGraphics:

GeoGraphics[{EdgeForm[Black], FaceForm[Red], 
  Polygon[Entity["Country", "Germany"]], 
  Polygon[Entity["Country", "Turkey"]]}]

[esleesma (Eileen Sleesman)]

Thank you so much!

[dreiss (David Reiss)]

Also you can control the geographical area of the shown map using the GeoRange option as in:

GeoGraphics[{EdgeForm[Black], FaceForm[Red], 
  Polygon[Entity["Country", "Germany"]], 
  Polygon[Entity["Country", "Turkey"]]}, 
 GeoRange -> Quantity[2000, "km"]]

And also recenter the graph using GeoCenter as in:

GeoGraphics[{EdgeForm[Black], FaceForm[Red], 
  Polygon[Entity["Country", "Germany"]], 
  Polygon[Entity["Country", "Turkey"]]}, 
 GeoRange -> Quantity[2000, "km"], 
 GeoCenter -> 
  Entity["City", {"Bonn", "NorthRhineWestphalia", "Germany"}]]

or

GeoGraphics[{EdgeForm[Black], FaceForm[Red], 
  Polygon[Entity["Country", "Germany"]], 
  Polygon[Entity["Country", "Turkey"]]}, 
 GeoRange -> Quantity[2500, "km"], GeoCenter -> GeoPosition[{45, 0}]]

[Vitaliyk (Vitaliy Kaurov)]

In order for the folks here to help you “to get a correct output” they need to see your input - hard to debug without code.

GerTur = GeoListPlot[
  {Entity["Country", "Turkey"], Entity["Country", "Germany"]},
  ImageSize -> 1000,
  GeoZoomLevel -> 6,
  GeoLabels -> Automatic,
  LabelStyle -> 20,
  PlotStyle -> 
   Directive[EdgeForm[Directive[Thick, Red]], Opacity[.2], Blue]]