# Prove this limit

**URL:** <https://community.wolfram.com/t/prove-this-limit/4398>\
**Category:** Questions\
**Created:** [December 26, 2014, 12:47am UTC](https://community.wolfram.com/t/prove-this-limit/4398 "2014-12-26T00:47:13Z")\
**Posts on this page:** 5\
**Page:** 1

<div class="post-metadata">

**Author:** ![bmmmburns](https://yyz1.discourse-cdn.com/wolfram/user_avatar/community.wolfram.com/bmmmburns/32/3126_2.png) [@bmmmburns](https://community.wolfram.com/u/bmmmburns)\
**Post date:** [December 26, 2014, 12:47am UTC](https://community.wolfram.com/t/prove-this-limit/4398/1 "2014-12-26T00:47:13Z")

</div>

Can someone prove this limit for me? It would help in future calculations of the MRB constant.

```
Limit[(3 + 2 Sqrt[2])^x - 2 Cos[x ArcCos[3]], x -> Infinity]==0

```

Here is my latest formula for calculating the MRB constant:

```
(*Fastest (at MRB's end) as of 24 dEC 2014.*)
prec = 20000;(*Number of required decimals.*)ClearSystemCache[];
T0 = SessionTime[];
expM[pre_] := 
  Module[{a, d, s, k, bb, c, n, end, iprec, xvals, x, pc, cores = 12, 
    tsize = 2^7, chunksize, start = 1, ll, ctab, 
    pr = Floor[1.005 pre]}, chunksize = cores*tsize;
   n = Floor[1.32 pr];
   end = Ceiling[n/chunksize];
   Print["Iterations required: ", n];
   Print["end ", end];
   Print[end*chunksize]; d = Cos[n ArcCos[3]];
   {b, c, s} = {SetPrecision[-1, 1.1*n], -d, 0};
   iprec = Ceiling[pr/27];
   Do[xvals = Flatten[ParallelTable[Table[ll = start + j*tsize + l;
        h = Log[ll]/ll; x = N[Exp[h], iprec];
        pc = iprec;
        While[pc < pr, pc = Min[3 pc, pr];
         x = SetPrecision[x, pc];
         y = x^ll - ll;
         x = x (1 - 2 y/((ll + 1) y + 2 ll ll));];(*N[Exp[Log[ll]/ll],
        pr]*)x, {l, 0, tsize - 1}], {j, 0, cores - 1}, 
       Method -> "EvaluationsPerKernel" -> 4]];
    ctab = ParallelTable[Table[c = b - c;
       ll = start + l - 2;
       b *= 2 (ll + n) (ll - n)/((ll + 1) (2 ll + 1));
       c, {l, chunksize}], Method -> "EvaluationsPerKernel" -> 2];
    s += ctab.(xvals - 1);
    start += chunksize;
    Print["done iter ", k*chunksize, " ", SessionTime[] - T0];, {k, 0,
      end - 1}];
   N[-s/d, pr]];
t2 = Timing[MRBtest2 = expM[prec];]; MRBtest2

```

I found the

```
Limit[Cos[n ArcCos[3]]/Cos[(n - 1) ArcCos[3]], n -> Infinity]=3 + 2 Sqrt[2].

```

---

<div class="post-metadata">

**Author:** ![sukrause](https://yyz1.discourse-cdn.com/wolfram/user_avatar/community.wolfram.com/sukrause/32/41348_2.png) [@sukrause](https://community.wolfram.com/u/sukrause)\
**Post date:** [December 26, 2014, 8:17pm UTC](https://community.wolfram.com/t/prove-this-limit/4398/2 "2014-12-26T20:17:33Z")

</div>

In principle that goes that way:

```
In[2]:= ArcCos[3] // N
Out[2]= 0. + 1.76275 I

```

\cos(z)=\frac{1}{2}(\exp(iz)+\exp(-iz)) by definition with z=x \arccos(3) it follows 2 \cos(x \arccos(3)) \sim \exp(1.76275 x) for big x. Now one needs only \exp(1.76275) \equiv 3 + \sqrt{2} which fits seemingly

```
In[4]:= E^1.76275 // N
Out[4]= 5.82844

In[5]:= 3 + 2 Sqrt[2] // N
Out[5]= 5.82843

```

or written more careful

```
In[8]:= N[E^Im[ArcCos[3]], 30] - N[3 + 2 Sqrt[2], 30]
Out[8]= 0.*10^-29

```

this might have even a geometrical proof, because the x has gone out of it.

---

<div class="post-metadata">

**Author:** ![bmmmburns](https://yyz1.discourse-cdn.com/wolfram/user_avatar/community.wolfram.com/bmmmburns/32/3126_2.png) [@bmmmburns](https://community.wolfram.com/u/bmmmburns)\
**Post date:** [December 27, 2014, 3:50pm UTC](https://community.wolfram.com/t/prove-this-limit/4398/3 "2014-12-27T15:50:37Z")

</div>

I guess this is a simpler way of proving Limit[(3 + 2 Sqrt[2])^x - 2 Cos[x ArcCos[3]], x → Infinity]==0:

```
In[10]:= FullSimplify[(3 + 2 Sqrt[2])^x - 2 Cos[x ArcCos[3]]]

Out[10]= -(3 + 2 Sqrt[2])^-x
 which of course goes to 0 as x-> Infinity.

```

I would still like to see a geometric proof, though.

---

<div class="post-metadata">

**Author:** ![sukrause](https://yyz1.discourse-cdn.com/wolfram/user_avatar/community.wolfram.com/sukrause/32/41348_2.png) [@sukrause](https://community.wolfram.com/u/sukrause)\
**Post date:** [December 28, 2014, 11:24am UTC](https://community.wolfram.com/t/prove-this-limit/4398/4 "2014-12-28T11:24:18Z")

</div>

> I would still like to see a geometric proof, though.

It turns out just by definition: It remained to show \exp(-i \arccos(3))=3+2\sqrt{2}. With the definition of [InverseCosine](http://mathworld.wolfram.com/InverseCosine.html), eq. (2), \arccos(z)=\frac{\pi}{2}+i\ln(iz+\sqrt{1-z^2}) one has \exp(-i(\frac{\pi}{2}+i \ln(i 3 + \sqrt{-8})))=\exp(-i(\frac{\pi}{2}+i\ln(i (3+2\sqrt{2}))))=\exp(-i(\frac{\pi}{2}+i\frac{i \pi}{2}+i\ln(3+2\sqrt{2})))=3+2\sqrt{2} \Box

---

<div class="post-metadata">

**Author:** ![sukrause](https://yyz1.discourse-cdn.com/wolfram/user_avatar/community.wolfram.com/sukrause/32/41348_2.png) [@sukrause](https://community.wolfram.com/u/sukrause)\
**Post date:** [December 28, 2014, 12:02pm UTC](https://community.wolfram.com/t/prove-this-limit/4398/5 "2014-12-28T12:02:40Z")

</div>

Bad luck, I typed too much

```
In[33]:= ComplexExpand[Exp[-I ArcCos[3]]]
Out[33]= 3 + 2 Sqrt[2]

```

life can be so easy … and if one does

```
In[35]:= ComplexExpand[(3 + 2 Sqrt[2])^x - 2 Cos[x ArcCos[3]]]
Out[35]= (3 + 2 Sqrt[2])^x - 2 Cosh[x Log[3 + 2 Sqrt[2]]]

```

one sees the result directly because of the definition of `Cosh` and with

```
In[38]:= TrigToExp[ComplexExpand[(3 + 2 Sqrt[2])^x - 2 Cos[x ArcCos[3]]]]
Out[38]= -(3 + 2 Sqrt[2])^-x

```

the result of `FullSimplify` reappears.