Radius of a circle bisecting the area of a given circle

Questions
,
1

I’m searching a Radius R of a circle, which bisects the area of a given circle with radius r. The center of the searched circle ( radius R) lies on the circumference of the given circle ( radius r). I’ve problems with the integration limits arcsin(R/2r) and pi-arcsin(R/2r) of the solve function. Has anyone an idea, how to do this with mathematica ? Thank you so much !

In[24]:= Part[Reduce[2 r Sin[x] == R, x], 2]

Out[24]= C[1] \[Element] Integers && 
 r != 0 && (x == \[Pi] - ArcSin[R/(2 r)] + 2 \[Pi] C[1] || 
   x == ArcSin[R/(2 r)] + 2 \[Pi] C[1])

Solve[2 r Sin[x] == R, x]

{{x -> ConditionalExpression[\[Pi] - ArcSin[R/(2 r)] + 2 \[Pi] C[1], 
    C[1] \[Element] Integers]}, {x -> 
   ConditionalExpression[ArcSin[R/(2 r)] + 2 \[Pi] C[1], 
    C[1] \[Element] Integers]}}

In[19]:= Part[{{x -> 
    ConditionalExpression[\[Pi] - ArcSin[R/(2 r)] + 2 \[Pi] C[1], 
     C[1] \[Element] Integers]}, {x -> 
    ConditionalExpression[ArcSin[R/(2 r)] + 2 \[Pi] C[1], 
     C[1] \[Element] Integers]}}, 1]

Out[19]= {x -> 
  ConditionalExpression[\[Pi] - ArcSin[R/(2 r)] + 2 \[Pi] C[1], 
   C[1] \[Element] Integers]}

Integrate[x, {x, R, 2 r Sin[s]}]

-(R^2/2) + 2 r^2 Sin[s]^2

In[22]:= Solve[
 Integrate[
   x, {x, R, 
    2 r Sin[s]}, {s, Reduce[2 r Sin[x] == R, x], 
     Reduce[2 r Sin[x] == R, x]} ] == Pi/2 r r, R]
2

I’m searching a Radius R of a circle, which bisects the area of a given circle with radius r.

In general, the area of the intersection is going to depend not only on r and R but on the distance between the two circle centers. Is there some assumption to be made, for example that the circles intersect each other orthogonally or maybe that one passes through the center of the other?

Finding an expression for the intersection area using Integrate should be possible, but solving the resulting transcendental equation for R might not be.

3

Hi Ilian,
Thank you for your answer. You are right indeed. The center of the searched circle with radius R lies on the cicumference of the given circle with radius r. ( is that, what you mean with ortgogonally intersection ?) And you are right too that the resulting equation can only be solved numerical ( Newton Raphson for example ) The solution is R/r = 1.1587
But I’ve problems to verify this with mathematica ( because I use the program only since two days )
I have problems with the integration limits of the angle phi. I want integrate from phi=arcsin (R/2r) to pi-arcsin(R/2r) ( I’ve done the integration in polar coordinates ‘by hand’)
It would be nice, if you perhaps could give me some hints how to do this with mathematica! Thank you very much again and have a nice time.
Peter

4

Thank you for the clarification. This can be conveniently done in Cartesian coordinates, using the Boole function. We can assume r = 1 without loss of generality, then

area[R_] = Integrate[Boole[x^2 + y^2 <= 1 && (x - 1)^2 + y^2 <= R^2], 
         {x, -1, 1}, {y, -1, 1}, Assumptions -> R > 0];

FindRoot[area[R] - Pi/2, {R, 1}, WorkingPrecision -> 20]

(* Out[4]= {R -> 1.1587284730181215178} *)

As for the polar form integral, that works fine too (I only changed the order of integration):

Integrate[x, {s, ArcSin[R/2 r], Pi - ArcSin[R/2 r]}, {x, R, 2 r Sin[s]}] // FullSimplify

(* Out[5]= (1/2) r^3 R Sqrt[4 - r^2 R^2] + (2 r^2 - R^2) ArcCos[(r R)/2] *)
5

Hi Ilian,
I cannot believe what I see and what you have done. I worked hours, days and weeks to find out the solution ( area integrals, trigonometric functions and so on) and you write down two rows and have it. I’ll now try to understand what you have done. Later on I’ll contact you. At the moment I can say nothing more … I’m missing every word to describe your job
Thank you so much ( it seems that I’m really to old )
Peter

6

Hi Peter,

This is another alternative. Less elegant than Ilians. But shows that a solution can be be found without integration.

Areaofintersectingcircles.jpg
Areaofintersectingcircles.jpg532×256 20.9 KB

7

Hi, Hans
thank you for your solution. I’ll try to understand it with the mathematica documentation.
Peter

8

after spending some time with mathematica I’ve found two other solutions without integration ( circlesegment,-sector)

In[13]:= Module[{a, b}, a = ArcCos[1 - R R/2]; b = ArcCos[R/2]; 
 FindRoot[2 a - Sin[2 a] + R R*(2 b - Sin[2 b]) == Pi, {R, 1, 1, 2}, 
  WorkingPrecision -> 20]]

Out[13]= {R -> 1.1587284730181215178}

In[14]:= Module[{a}, a = 2 ArcSin[R/2];
 FindRoot[R R (Pi - a)/4 + 1/2*(a - Sin[ a]) == Pi/4, {R, 1, 1, 2}, 
  WorkingPrecision -> 20]]


Out[14]= {R -> 1.1587284730181215178}

but for me, Ilian’s solution is the most brilliant one ( or how do you describe it in english) In other words: that’s for me ’ mathematics at it’s finest’