Removal of Complex Background from Image

Questions
1

Hello,

What I want to do is to remove complex background from an image attached and only highlight or draw polygons around trees. I have tried and tried to highlight green color of trees to separate from the background and none was successful. I also attached a target image of what I roughly want to achieve. I really appreciate some inputs. Thank you very much.

TreeImage.jpg
TreeImage.jpg912×680 270 KB

TargetImage.PNG
TargetImage.PNG445×403 61.4 KB

2

Hi,

if the image is assigned to the variable img, then

ImageMultiply[
 Erosion[DeleteSmallComponents[
   GeodesicClosing[
    GeodesicOpening[
     AlphaChannel@RemoveBackground[img, {"Foreground", Brown}], 15], 
    10], 100], 8], img]

gives

ScreenShot2015-11-19at23.38.04.jpg
ScreenShot2015-11-19at23.38.04.jpg628×466 35.1 KB

DeleteSmallComponents[
ImageMultiply[
Erosion[DeleteSmallComponents[
GeodesicClosing[
GeodesicOpening[
AlphaChannel@RemoveBackground[img, {“Foreground”, Brown}], 15],
10], 100], 8], img], 1200]

removes the small components.

ScreenShot2015-11-19at23.39.37.jpg
ScreenShot2015-11-19at23.39.37.jpg625×465 32.9 KB

If you want a white background use:

RemoveBackground[
 DeleteSmallComponents[
  ImageMultiply[
   Erosion[DeleteSmallComponents[
     GeodesicClosing[
      GeodesicOpening[
       AlphaChannel@RemoveBackground[img, {"Foreground", Brown}], 15],
       10], 100], 8], img], 1200], {"Background", "Uniform"}]

ScreenShot2015-11-19at23.41.01.jpg
ScreenShot2015-11-19at23.41.01.jpg613×459 36.1 KB

You can colorise the individual trees (note that it doesn’t work right for two close trees in this image):

MorphologicalComponents[
  RemoveBackground[
   DeleteSmallComponents[
    ImageMultiply[
     Erosion[DeleteSmallComponents[
       GeodesicClosing[
        GeodesicOpening[
         AlphaChannel@RemoveBackground[img, {"Foreground", Brown}], 
         15], 10], 100], 8], img], 1200], {"Background", 
    "Uniform"}]] // Colorise

ScreenShot2015-11-19at23.43.50.png
ScreenShot2015-11-19at23.43.50.png626×464 27.4 KB

This here would count the trees (at least approximately):

Length[Select[
  ComponentMeasurements[
   MorphologicalComponents[
    RemoveBackground[
     DeleteSmallComponents[
      ImageMultiply[
       Erosion[DeleteSmallComponents[
         GeodesicClosing[
          GeodesicOpening[
           AlphaChannel@RemoveBackground[img, {"Foreground", Brown}], 
           15], 10], 100], 8], img], 1200], {"Background", 
      "Uniform"}]], "Area"], #[[2]] > 1000 &]]

In this case it gives 12 which corresponds to the large coloured areas in the last image. Hence, it only counts well separated trees.

Cheers,

Marco

3

Hi all,

removing a complex background can be a difficult task; therefore Marco’s nice solution can hardly be shorter.
If one concentrates on the fact that due to snow the background is basically gray and the trees stay (at least a little bit) green, things get much easier (though I am not sure that this approach answers the original question):

greenQ[p : {r_, g_, b_}] := With[{mean = Mean[p]}, If[g > 1.03 mean, 1, 0]]
mask = Erosion[Dilation[ImageApply[greenQ, img], 4], 4]

this gives a “mask” for green trees. Lets check:

greenTrees.jpg
greenTrees.jpg614×484 149 KB

Regards – Henrik

4

Dear Henrik,

that is a fantastic solution! A great and clean separation which captures all details. Very nice. I see that, should Inever have an image processing problem, I should ask you!

Thanks for sharing,

M.

5

Hi Marco and Henrik,

Both approaches are fantastic to me! I really want to study both of your codings.

Again, thank you very much!

Eiji