[Solved] "The first argument is expected to be a string, a valid..."

Questions
1

First day trying out cloud notebooks.

Unsure why this produces an error:

CloudDeploy[FormFunction[{{"input","Comma Separated Words or Phrases"}->"String"},Sort[WordFrequencyData[{#input}],Greater]]]
2

Hi Casey,

There are a couple of problems. A function needs to be passed to FormFunction and the function receives a single string, not a list of strings. Add a & to create a pure function and use StringSplit to generate the list of strings.

FormFunction[{{"input", "Comma Separated Words or Phrases"} -> "String"}, 
 Sort[WordFrequencyData[StringSplit[#input, ","]], Greater] &]
3

Thank you,

I found StringTrim helpful here to:

CloudDeploy[FormFunction[{
"input" -> <|"Label" -> "Synonyms","Hint" ->"Comma or Pipe Separated Words and Phrases"|>
},Sort[WordFrequencyData[StringTrim[StringSplit[#input, {",","|"}]]], Greater] &]]

Is there a ‘simple’ way to have the output of this appear tabular?

4

Here are a few ways

WordFrequencyData[{"cat", "dog", "mouse"}] // Dataset

3778plot.png
3778plot.png215×140 2.52 KB

WordFrequencyData[{"cat", "dog", "mouse"}] // 
  KeyValueMap[<|"Word" -> #, "Frequency" -> #2|> &] //
  Dataset

3676plot.png
3676plot.png215×172 3.43 KB

WordFrequencyData[{"cat", "dog", "mouse"}] // 
  KeyValueMap[{#, #2} &] //
  Prepend[Style[#, Bold] & /@ {"Word", "Frequency"}] // 
  Grid[#, Frame -> All, Background -> {None, {Yellow}}] &

4939plot.png
4939plot.png195×106 5.78 KB

5

Thank you, super helpful.

I’m happy with this for the moment:

CloudDeploy[FormFunction[
{"input" -> <|"Label" -> "Synonyms","Hint" ->"Comma or Pipe Separated Words and Phrases"|>},
Dataset[Sort[WordFrequencyData[StringTrim[StringSplit[#input, {",","|"}]]], Greater]] &,
"Table"]]