Solving nonlinear equation with integrals and beta functions

Questions
, , , ,
1

GINI.jpg
GINI.jpg1087×298 33.8 KB

Hello! I am new to Mathematica. Does anybody here know how to solve (for alpha) this equation? I find it very difficult. I have tried to use NSolve[ ] and Solve[ ]. But it does not work.

2

Try minimizing the square of the difference.

alpha=.;t=.; (* remove any cached previous values *)
Quiet[
  NMinimize[{
    ((1-4 NIntegrate[t^(1-1/alpha)(1-t)^(1/alpha),{t,0,1/2}]/
    NIntegrate[t^(-1/alpha)(1-t)^(1/alpha),{t,0,1/2}])-0.2455)^2,1<alpha<5},
  alpha]]

which returns

{4.52028*^-18,{alpha->2.93201}}

and

alpha=.;t=.;
ListPlot[Table[{alpha,((1-4 NIntegrate[t^(1-1/alpha)(1-t)^(1/alpha),{t,0,1/2}]/
    NIntegrate[t^(-1/alpha)(1-t)^(1/alpha),{t,0,1/2}])-0.2455)^2},{alpha,1,5,1/8}]]

which will give you an idea how this behaves.

The reason for the Quiet is that it complains about complex numbers for some of your powers. Usually I don’t like hiding warning messages when doing things like this, but this can at least show you a result.

Remember there are always at least six different ways of doing anything in Mathematica.

3

Here is a way:

Clear[alpha, f];
f[alpha_] =
 (1 - 4  Integrate[t^(1 - 1/alpha) (1 - t)^(1/alpha),
      {t, 0, 1/2}, Assumptions -> alpha > 1]/
     Integrate[t^(-1/alpha) (1 - t)^(1/alpha),
      {t, 0, 1/2}, Assumptions -> alpha > 1])
Plot[f[alpha], {alpha, 1, 4}, GridLines -> {None, {.2455}}]
Solve[f[alpha] == .2455 && 2 < alpha < 3, alpha]
4

Thank you! You have helped me a lot. BTW, what do you mean by " there are always at least six different ways of doing anything in Mathematica." ?

5

New users may not understand why the method they tried to use to solve a problem did not work. And they are sometimes surprised when they are given several completely different ways of solving the problem. Sometimes there may be as many as ten completely different ways of solving a problem. Some of those may be very difficult to understand.

6

So, for the problem that I have asked, what are other method that you know that will work? I am curious BTW.

7

Try

Assuming[alpha>1,expr=1-2455/10^4==4Integrate[t^(1-1/alpha)(1-t)^(1/alpha),{t,0,1/2}]Integrate[t^-(1/alpha)(1-t)^(1/alpha),{t,0,1/2}]]
FindRoot[expr,{alpha,2}]

and

FindInstance[1-2455/10^4==4Integrate[t^(1-1/alpha)(1-t)^(1/alpha),{t,0,1/2}]Integrate[t^-(1/alpha)(1-t)^(1/alpha),{t,0,1/2}]&&alpha>2,alpha]

There should be ways to get NSolve and Solve to do this for you.

And there will be even more ways of doing this.