Styling of boundaries in ParametricPlot3D[ ] ?

[erikmahieu]

I am trying to get control over the different parts of the boundaries in a Parametric3D as here:

ParametricPlot3D[{v, Cos[t], Sin[t]}, {t, 0, 2 Pi}, {v, -3, 3}, 
 PerformanceGoal -> "Quality", 
 PlotStyle -> {FaceForm[Directive[Opacity[1], Green], 
    Directive[Opacity[1], Lighter[Magenta, .25]]]}, Boxed -> False, 
 Axes -> False, Mesh -> None, 
 RegionFunction -> Function[{x, y, z}, x^2 + z^2 > .35], 
 BoundaryStyle -> AbsoluteThickness[3]]

I want to keep only the boundary in the circular hole cut by another cylinder and get rid of the two extreme circular boundaries and the horizontal line boundary on the main cylinder.

My question: is there a way to control separate parts of these 3 boundary sections and style (or delete) them differently?

[Vitaliyk (Vitaliy Kaurov)]

I think you just have to specify the boundary you need via a different mechanism. For more details see this and this. For example:

ParametricPlot3D[{v,Cos[t],Sin[t]},{t,0,2 Pi},{v,-3,3},
PlotPoints->30,Boxed->False,Axes->False,
PlotStyle->{
	FaceForm[Directive[Opacity[1],Green],
	Directive[Opacity[1],Lighter[Magenta,.25]]]},
RegionFunction->Function[{x,y,z},x^2+z^2>.35],
Mesh -> {{.01}},
MeshStyle->Directive[Thickness[.01],Black],
MeshFunctions->{Function[{x,y,z},x^2+z^2-.35]}]

[erikmahieu]

Works perfectly. Got confused between Mesh and Boundary but now I even understand the why of your “Mesh->{{.01}}” ! Thanks!