Suppress HyperGeometric solution?

Questions
1

Integrate[1/Sqrt[ X^3+1] , x]

This always gives a Hypergeometric solution.
Can it be forced to calculate an Elliptic Integral solution?

Thanks,
Richard

2

Using Rubi ( see Rubi - The Rule-based Integrator for Mathematica ), one obtains

Needs@"Rubi`"

int2 = Int[1/Sqrt[x^3 + 1], x]
(*
(2 Sqrt[2 + Sqrt[3]] (1 + x) Sqrt[(1 - x + x^2)/(1 + Sqrt[3] + x)^2]
  EllipticF[
  ArcSin[(1 - Sqrt[3] + x)/(1 + Sqrt[3] + x)], -7 - 4 Sqrt[3]])/(3^(
 1/4) Sqrt[(1 + x)/(1 + Sqrt[3] + x)^2] Sqrt[1 + x^3])
*)

For x > -1, the hypergeometric solution is equal to int2 - (int2 /. x -> 0). However, the hypergeometric solution has simpler branch cuts and differs from this (by a locally constant function) on the whole complex plane. Consequently, the two solutions cannot be simplified into each other. The elliptic function solution can be simplified with the assumption x > -1:

FullSimplify[int2, x > -1]
(*
2 Sqrt[1 + 2/Sqrt[3]]
  EllipticF[ArcSin[1 - (2 Sqrt[3])/(1 + Sqrt[3] + x)], -7 - 4 Sqrt[3]]
*)

The hypergeometric solution cannot be simplified into this form under the assumption, since, as an expression tree, it is simpler than the elliptic function expression. I don’t know how to get an elliptic function solution using just the built-in functionality.

3

Just as a curios observation, we could make integral “close” to elliptic with some Möbius transformation.
I’ve just played with it, like this:

Clear[u, t, x]; u = t/(1 + t);

FullSimplify[
 Integrate[FullSimplify[D[u, t]/Sqrt[1 + u^3]], t] /. 
  Solve[x == u, t]]

(*(2 (2 + (-1)^(2/3)) Sqrt[((1 + (-1)^(2/3) - x) (1 + x))/(2 + (-1)^(
   2/3))^2] Sqrt[(-1 + (-1)^(1/3) + x)/(-2 + (-1)^(1/3))]
  EllipticF[ArcSin[Sqrt[(1 + x)/(2 + (-1)^(2/3))]], 
  1/2 (1 + I Sqrt[3])])/Sqrt[1 + x^3]*)

I’m sure one can find a transformation that gives the simplest result, but I don’t know how (