Message Boards Message Boards

GROUPS:

[GIF] Flat (Stereographic projection of flat torus)

Posted 1 year ago
1933 Views
|
1 Reply
|
6 Total Likes
|

Stereographic projection of flat torus

Flat

This is very much in the spirit of Send/Receive, but one dimension up. Now, I'm taking the surface $(\cos \theta \cos t, \cos \theta \sin t, \sin \theta \cos t, \sin \theta \sin t)$ inside the 3-sphere (which is just a flat torus, a rotated copy of the standard Clifford torus) as represented by the $\theta$- and $t$-coordinate grid lines, and stereographically projecting down to 3-space (actually, to produce the final animation, I'm then orthogonally projecting to the plane, which is what the [[;;2]] things are doing).

Here's the code:

Stereo[p_] := 1/(1 - p[[-1]]) p[[;; -2]]

With[{n = 15, cols = RGBColor /@ {"#de3d83", "#00b8b8", "#001F3F"}},
 Manipulate[
  Graphics[
   {Thickness[.0045],
    Table[
     {Blend[cols[[;; 2]], 1/2 Cos[2 (θ + s)] + 1/2],
      Line[
       Table[
        Stereo[{Cos[θ + s] Cos[t], Cos[θ + s] Sin[t], Sin[θ + s] Cos[t], Sin[θ + s] Sin[t]}][[2 ;;]],
        {t, 0, π, π/200}]]},
     {θ, 0, 2 π - π/n, π/n}],
    Table[
     {Blend[cols[[;; 2]], 1/2 Sin[2 (t + s)] + 1/2],
      Line[
       Table[
        Stereo[{Cos[θ] Cos[t + s], Cos[θ] Sin[t + s], Sin[θ] Cos[t + s], Sin[θ] Sin[t + s]}][[2 ;;]],
        {θ, 0, π, π/200}]]},
     {t, 0, 2 π - π/n, π/n}]},
   PlotRange -> 3, ImageSize -> 540, Background -> cols[[-1]]],
  {s, 0, π/n}]
 ]

enter image description here - Congratulations! This post is now a Staff Pick as distinguished by a badge on your profile! Thank you, keep it coming!

Reply to this discussion
Community posts can be styled and formatted using the Markdown syntax.
Reply Preview
Attachments
Remove
or Discard

Group Abstract Group Abstract