Message Boards Message Boards

35
|
22595 Views
|
9 Replies
|
78 Total Likes
View groups...
Share
Share this post:

Wolfram Research at SXSW

Posted 10 years ago
We are having a blast in the Wolfram booth at SXSW

Yesterday was our opening day, and we were thrilled to see so many friends - old and new - stop by to say hello and see what we've been up to.
Visitors came to the booth with coding challenges for our live coders. Here are some neat examples, built with the Wolfram Language.

10 map projections of the world:
Grid[
Partition[
  GeoGraphics[{}, GeoRange -> "World", GeoProjection -> #, GeoGridLines -> Automatic] & /@ GeoProjectionData[][[;; 10]],
  5
  ]
]


Countries in the world, colored by GDP:
GeoRegionValuePlot[Thread[CountryData[] -> EntityValue[CountryData[], "GDP"]]]


Pop art:
Colorize[ImageForestingComponents[ExampleData[{"TestImage", "House2"}], Automatic, 10]]


Intel stock value over time:
DateListPlot[TimeSeries[FinancialData["INTC", "Jan. 1, 2000"]]]


Length of words in Beowolf, Old English vs. Modern:
Histogram[{
  StringLength /@
   StringSplit[ExampleData[{"Text", "BeowulfOldEnglish"}]],
  StringLength /@ StringSplit[ExampleData[{"Text", "BeowulfModern"}]]
  },
ChartLegends -> {"Old English", "Modern"}
]


How warm it is today:
IconData["AirTemperature", AirTemperatureData[UnitSystem -> "Imperial"]]


Relief plot of Austin, TX:
ReliefPlot[QuantityMagnitude[GeoElevationData[Entity["City", {"Austin", "Texas", "UnitedStates"}]]]]


And the shortest tour of large cities in France:
coordinates = EntityValue[CityData[{Large, "France"}], "Coordinates"];
tour = Last[FindShortestTour[coordinates]];
GeoGraphics[{Red, Thick, Line@coordinates[[tour]]}]


We are excited to see what coding challenges we will tackle in our booth this week. Stop by, say hello, and write code with us! 
POSTED BY: Erin Craig
9 Replies
Posted 10 years ago
Stephen Wolfram blogs on Injecting Computation Everywhere at SXSW

Stephen Wolfram has just posted a “speaker’s cut” of his SXSW talk transcript on his blog. It includes examples of the Wolfram Language in action taken from his featured talk in Austin earlier this month:
  •     Tweeting images using the Wolfram Language
  •     Classifying and interpreting hand-written digits
  •     Symbolically nesting an interface element to create a fractal interface
  •     Creating an app that displays images as seen through the eyes of a cat or dog
Moving from simple to more complex features and programs, Stephen also introduces new Wolfram technologies, highlighting what’s possible with the Wolfram Programming Cloud, the Wolfram Data Science Platform, the Wolfram Data Framework, the Wolfram Connected Devices Project, and more.

To see all of his demos and examples, you’ve got to read the full post.
POSTED BY: Emily Suess
We are happy to see so many people excited about the Wolfram Language! We have had so much fun in the booth playing with the Wolfram Language and seeing what it can do - we can't wait to share it with people all over the world.

Yesterday, we used a webcam and wrote a program that detects faces as they move in front of the camera. You can even try this out in Mathematica, version 9
Dynamic[
image = CurrentImage[];
faces = FindFaces[image, {100, 1000}];
Show[{image, Graphics[{EdgeForm[{Red, Thick}], FaceForm[], Rectangle @@@ faces}]}]
]


People stopped by the booth asking us to find the countries in Latin America. So we did:
CountryData["LatinAmericaCaribbean"]


And then we wanted to see their flags: 
Show[CountryData[#, "Flag"], ImageSize -> 50] & /@
CountryData["LatinAmericaCaribbean"]


But which flag is for which country? We added tooltips:
Tooltip[Show[CountryData[#, "Flag"], ImageSize -> 50], #] & /@
CountryData["LatinAmericaCaribbean"]


And this gave rise to the idea of a map of the world, using country flags:
 With[{world = CountryData[]},
  GeoGraphics[{EdgeForm[Black],
    Append[
     Transpose[{
       GeoStyle["Image", #] & /@ EntityValue[world, "Flag"],
       EntityValue[world, "Polygon"]
       }],
     {GeoStyle["Image",
       EntityValue[Entity["Country", "UnitedStates"], "Flag"]],
     EntityValue[Entity["USState", "Alaska"], "Polygon"]}
    ]},
  GeoBackground -> GeoStyle["ReliefMap"]
  ]
]


Here's a web form that guesses your age and makes a PNG, based on your name:
 CloudDeploy[
  FormFunction[
   {"name", "Enter name"} -> "GivenName",
 
   Row[{"You are probably ",
      EntityValue[
        #name,
        EntityProperty["MostCommonAge", SourceEntityType -> "GivenName", FormatName -> "most common age"]],
   " old"}] &,

  "PNG"
  ]
]

Hitting "Submit" gives me a webpage with this:



And instead of FormFunction, we could have used APIFunction to build this as an API:
 CloudDeploy[
  APIFunction[
   {"name" -> "GivenName"},
  
   Row[{"You are probably ",
      EntityValue[#name,
       EntityProperty["MostCommonAge", SourceEntityType -> "GivenName",
         FormatName -> "most common age"]], " old"}] &,
  
  "PNG"
  ]
]

We are sad to say that today is the last day of our trade show - we are so enjoying our time in Austin and at SXSW, and we love sharing Wolfram Language with new people. Come say hi!
POSTED BY: Erin Craig
Posted 10 years ago
Great set of examples here. Really impressive that these were more or less developed and written on the fly at the request of booth visitors. I'm amazed by how intuitive (and powerful) the Wolfram Language is.

Add this to the number of briliant and innovative people that have stopped by, and the Wolfram booth has been a blast!
POSTED BY: Jared Fritz
That's really exciting! Thanks for sharing these neat examples :-) 

What can you do with Wolfram Language and a webcam?

Here is my little live coding that produces a time-lapse animation from one of Yosemite's webcams http://www.yosemiteconservancy.org/webcams/high-sierra
Run a scheduled task to import the images every two minutes during 18 hours:
frames = {};
RunScheduledTask[frames = Join[frames, {Import["http://pixelcaster.com/yosemite/webcams/sentinel.jpg"]}], {120,540}]
And then Export the collected frames as an animated GIF:
Export["timelapse.gif", Join[frames, Reverse[frames]]]



You will be able to share it with everyone using CloudDeploy:
CloudDeploy[ExportForm[Import[Export["timelapse.gif", frames]], "GIF"], Permissions -> "Public"]

There are thousands of webcams out there. Find one that you like and let me know what kinds of stunning time-lapse animations are you able to produce. For example, try using this webcam from Chicago http://wwc.instacam.com/instacamimg/CHBSC/CHBSC_l.jpg

Enjoy,
Bernat
POSTED BY: Bernat Espigulé
Day two at SXSW came and went too quickly! The booth was busy all day with people excited to see the Wolfram Language in action.
We had a fun day. We connected Mathematica to an arduino and made an instant API to display real time data from the arduino's accelerometer. And we worked on a program to compare recorded sound to a MIDI file to see if the recorded sound is "in tune"!
Here are a few more examples from today.

Make a form to illustrate the path between two cities:
CloudDeploy[
FormFunction[
   {{"city1", "first city"} -> "City", {"city2", "second city"} -> "City"},
    GeoListPlot[{#city1, #city2}, Joined -> True] &,
    "JPG"
]
]
The output of the above is something like this:
CloudObject["www.thisisaurl.com/identifiers"]

Where this URL gives a webpage with the form:

And submitting the form gives you the path between the cities:


Or, you can blur faces from a photograph:
image = ExampleData[{"TestImage", "Couple"}];
faces = FindFaces[image];
blurred = GaussianFilter[ImageTrim[image, #], 10] & /@ faces;
Fold[Function[{i, o}, ImageCompose[i, #1, Mean[#2]] & @@ o], image, Transpose[{blurred, faces}]]


Or graph the temperature in Austin from 1980 to 2013:
WeatherData["Austin", "Temperature", {{1980, 1, 1}, {2013, 12, 31}, "Month"}]
DateListPlot[%]


You can convert natural language to Wolfram language:
Interpreter["City"]["NYC"]
Interpreter["Date"]["1-4-87"]


And bring chemistry to life:
ChemicalData["Caffeine", "MoleculePlot"]
Manipulate[
Labeled[ChemicalData[chemical, "MoleculePlot"], ChemicalData[chemical, "MolecularWeight"], Bottom],
{chemical, ChemicalData[][[;; 10]]}
]



Come visit our booth today - we are planning some cool live coding: what can you do with Wolfram Language and a webcam?
POSTED BY: Erin Craig
It's been really interesting to talk to people at SXSW who are seeing the Wolfram Language for the first time and only have knowledge of WolframAlpha.com - I think they'll end up doing some really neat things!
POSTED BY: Kelvin Mischo
Between Stephen Wolfram's announcement of so many cool new additions to the technology stack and the AMAZING live coders in the booth (Exhibit Hall 3, Booth 338 if you're in Austin) - this week has been a whirlwind.  While the code above was being built, the crowd simply stared in awe - it was a beautiful thing to behold.
Please stay tuned, we'll be here another 2 days!
emoticon
POSTED BY: Danielle Rommel
You can definitely tell the developers put many efforts into switching from traditional coding to knowlege based programming. These concise implementations are best demonstration of this profound idea!

Users now can create many useful examples with no more codes than the illustrated above. 
POSTED BY: Shenghui Yang
Barely seems like we're programming anymore - more like writing haiku!

btw, the second example can be made even shorter:
GeoRegionValuePlot[CountryData[] -> "GDP"]
POSTED BY: Peter Barendse
Reply to this discussion
Community posts can be styled and formatted using the Markdown syntax.
Reply Preview
Attachments
Remove
or Discard

Group Abstract Group Abstract