And here it is:

A curve of constant width, such as the Reuleaux triangles, can be generated from any polygon. From any point there is another point at distance 1 with no points at a greater distance.

In 3D, the problem is much harder. The sphere is a solid of constant width. If spherical curves are added to a tetrahedron, midpoints of opposing edges are at a distance greater than 1 apart. This flaw can be fixed with the special curve-smoothing techniques of the Meissner tetrahedra. Several curves of constant width can be the basis of a solid of revolution to produce a solid of constant width.

According to the paper "On Curves and Surfaces of Constant Width" by Howard L. Resnikoff, that's pretty much it. His paper introduces a few new possible surfaces, such as this one.

SphericalPlot3D[1 + 1/10 Cos[3 t] Sin[3 u] Sin[u]^2, {u, -Pi, Pi}, {t, -Pi, Pi}, Boxed -> False, SphericalRegion -> True, ViewAngle -> Pi/10, ImageSize -> {600, 600}, Mesh -> None, Axes -> False, PlotPoints -> 200]

Is that really a solid of constant width? Let's make a function to find farthest points.

FarthestPoints[pts_List, singlepoint_, num_] := SortBy[Complement[pts, Nearest[pts, singlepoint, Length[pts] - num ]], -MyEuclidean[singlepoint, #] &];

Then we generate many points on this surface, and find the point that is farthest away.

resni = Flatten[Table[FromSphericalCoordinates[{(1 + 1/10 Cos[3 t] Sin[3 u] Sin[u]^2), u, t}], {u, .001, 3.14, .05}, {t, -3.14, 3.14, .1}], 1]; 
dists = Monitor[Table[EuclideanDistance[resni[[k]],FarthestPoints[resni,resni[[k]],1][[1]]],{k,1,Length[resni]}],k]; 
MinMax[dists]  

{1.99925, 2.07099}

Not the desired result. It's close to being a solid of constant width, but not nearly close enough.

Eleven months ago, I opened up the discussion Biggest Little Polyhedra, which led to a blog article on biggest little polyhedra, and eventually I improved results and made a Demonstration for biggest little polyhedra. I've had 1-3 computers steadily improving the results for nearly a year now.

In short, you have $n$ points in 3 space, no two more than 1 apart. What is the greatest volume that can be bounded with the $n$ points with unit diameter? The classic solution, widely published, is to use the Thomson problem solutions, but they are far from optimal. For example, with Thomson, 121 points are needed to bound a volume of 1/2. It turns out that 84 points with diameter 1 will suffice. One feature of the biggest little polyhedra is that they have lots and lots of unit length diagonals. Can they be used to make solids of constant width? With most of my smallest solutions there are problems similar to the trouble the tetrahedron has. There may be Meissner-like methods for fixing the flaws, but I haven't explored that yet.

During the long search, I came across the page Greater Self-Dual Solids. I especially liked the Self-Dual Icosioctahedron #4, and found that I could make a caltrop out of it, where every vertex was a unit distance from all corners of the opposing face. But it wasn't the optimal way to bound space with 28 points. Extending it to a solid of constant width caused the same sorts of flaws as the tetrahedron.

I extended that self dual polyhedron to one on 76 points with tetrahedral symmetry. Points 1, 13, 25, 29, 41, and 53 are as follows:

{{0.0833`, 0.0833`, 0.4930122817942774`},     (*{C1, C1, C4}*)
 {0.32530527130128584`, -0.20709494964790603`, 0.32530527130128584`},    (*{C3, -C0, C3}*)
{0.28875291001058745`, 0.28875291001058745`, 0.28875291001058745`},     (*{C2, C2, C2}*)
{-0.2142`, 0.40369721678726284`, -0.2142`},    (*{-C6, C5, -C6}*)
{-0.07272969962634213`, 0.35355339059327373`, -0.35355339059327373`},    (*{-C7, C8, -C8}*)
{0.07587339432355446`, 0.44185`, -0.23402687345687453`}}  (*{C9, C10, -C11}*)  

The full vertices are as follows. There is something more elegant using the tetrahedral group, but I haven't gotten to that yet.

cal76 ={{C1,C1,C4},{C1,-C1,-C4},{-C1,-C1,C4},{-C1,C1,-C4},{C4,C1,C1},{C4,-C1,-C1},{-C4,-C1,C1},{-C4,C1,-C1},{C1,C4,C1},{C1,-C4,-C1},{-C1,-C4,C1},{-C1,C4,-C1},

{C3,-C0,C3},{C3,C0,-C3},{-C3,C0,C3},{-C3,-C0,-C3},{C3,-C3,C0},{C3,C3,-C0},{-C3,C3,C0},{-C3,-C3,-C0},{C0,-C3,C3},{C0,C3,-C3},{-C0,C3,C3},{-C0,-C3,-C3},

{C2,C2,C2},{C2,-C2,-C2},{-C2,-C2,C2},{-C2,C2,-C2},

{-C6,C5,-C6},{-C6,C6,-C5},{-C5,C6,-C6},{-C6,-C5,C6},{-C6,-C6,C5},{-C5,-C6,C6},{C6,-C5,-C6},{C6,-C6,-C5},{C5,-C6,-C6},{C6,C5,C6},{C6,C6,C5},{C5,C6,C6},

{-C7,C8,-C8},{-C8,C8,-C7},{-C8,C7,-C8},{-C7,-C8,C8},{-C8,-C8,C7},{-C8,-C7,C8},{C7,-C8,-C8},{C8,-C8,-C7},{C8,-C7,-C8},{C7,C8,C8},{C8,C8,C7},{C8,C7,C8},

{C9,C10,-C11},{C9,C11,-C10},{-C10,C11,C9},{-C11,C10,C9},{-C11,-C9,-C10},{-C10,-C9,-C11},{C9,-C10,C11},{C9,-C11,C10},{-C10,-C11,-C9},{-C11,-C10,-C9},{-C11,C9,C10},{-C10,C9,C11},{-C9,-C10,-C11},{-C9,-C11,-C10},{C10,-C11,C9},{C11,-C10,C9},{C11,C9,-C10},{C10,C9,-C11},{-C9,C10,C11},{-C9,C11,C10},{C10,C11,-C9},{C11,C10,-C9},{C11,-C9,C10},{C10,-C9,C11}};

Here's what it looks like with all 150 unit diagonals added.

With the Farthest Point function from earlier, random points at unit distance can be added. For each random point on a sphere, we move it closer or farther from the origin so that the farthest point is at distance 1. The polar opposite is also generated.

randomUnitDistancePointPolar[pointset_] := Module[{k},With[{randomspherepoint = .54 coord[{RandomReal[{0,2Pi}],RandomReal[{-1,1}],1}]},{randomspherepoint(k/.Quiet[Solve[{MyEuclidean[k randomspherepoint, FarthestPoints[pointset,randomspherepoint,1][[1]]]==1,0<k<2}]][[1,1]]),(-randomspherepoint)(k/.Quiet[Solve[{MyEuclidean[k (-randomspherepoint), FarthestPoints[pointset,(-randomspherepoint),1][[1]]]==1,0<k<2}]][[1,1]])}]];  

Using the 76 points, a lot more points can be added.

is76scw = Table[randomUnitDistancePointPolar[cal76], {10000}];  

The crucial check -- are any two polar opposites more than 1 apart?

Select[is76scw, EuclideanDistance[#[[1]], #[[2]]] > 1 &]  

There are no flaws. So far as I know, this is the first solid of constant width that has been found with tetrahedral symmetry. To generate the image at the top, use

Graphics3D[ConvexHullMesh[Join[cal76,Flatten[is76scw,1]]]["GraphicsComplex"], Boxed-> False, ViewAngle-> Pi/10, ImageSize->{600,600} ]

And there you have it, a new solid of constant width. It's also the best known way to bound space with 76 points. Mathematica just needed to make a few trillion calculations, optimizations, and improvements over an eleven month period to find it.