Message Boards Message Boards

GROUPS:

Find formula of a Gamma[] product with complex conjugate pair of numbers?

Posted 11 months ago
940 Views
|
2 Replies
|
1 Total Likes
|

Wolfram Language knows about some simplifications for the product of the Gammafunction for complex conjugate numbers, i.e.

In[1]:= Gamma[n I] Gamma[-n I] // FullSimplify

Out[1]= (\[Pi] Csch[n \[Pi]])/n

In[2]:= Gamma[1 + n I] Gamma[1 - n I] // FullSimplify

Out[2]= n \[Pi] Csch[n \[Pi]]


In[3]:= Gamma[2 + n I] Gamma[2 - n I] // FullSimplify

Out[3]= n (1 + n^2) \[Pi] Csch[n \[Pi]]

In[4]:= Gamma[3 + n I] Gamma[3 - n I] // FullSimplify

Out[4]= n (4 + 5 n^2 + n^4) \[Pi] Csch[n \[Pi]]

In[5]:= Gamma[4 + n I] Gamma[4 - n I] // FullSimplify

Out[5]= Gamma[4 - I n] Gamma[4 + I n]

... but at some point it is stuck. With the help of WL I found these Identities for m=4,5 and 6.

In[8]:= N[Table[{Gamma[4 + n I] Gamma[
       4 - n I] == (\[Pi] n (n^6 + 14 n^4 + 49 n^2 + 36))/
     Sinh[n \[Pi]]}, {n, 1, 4}], 20]

Out[8]= {{True}, {True}, {True}, {True}}
In[9]:= N[
 Table[{Gamma[5 + n I] Gamma[
      5 - n I] == (\[Pi] n (n^8 + 30 n^6 + 273 n^4 + 820 n^2 + 576))/
    Sinh[n \[Pi]]}, {n, 1, 4}], 20]

Out[9]= {{True}, {True}, {True}, {True}}
In[10]:= N[
 Table[{Gamma[6 + n I] Gamma[
      6 - n I] == (\[Pi] n (n^10 + 55 n^8 + 1023 n^6 + 7645 n^4 + 
       21076 n^2 + 14400))/Sinh[n \[Pi]]}, {n, 1, 4}], 20]

Out[10]= {{True}, {True}, {True}, {True}}

And of course more identities for other natural numbers can be found with some effort. Maybe someone can find a closed formula. for the case Gamma[m+I n]Gamma[m-I n], where m is a natural number.

2 Replies

Hi

It's a simple formula because I found it in a few minutes.

HoldForm[Gamma[m + n I] Gamma[m - n I] == n π Csch[n π]*Product[(-1)^(2 j) (-n*I + j) (n*I + j ), {j, 1, m - 1}] == 
n π Csch[n π]*Pochhammer[1 - I n, -1 + m] Pochhammer[1 + I n, -1 + m]] // TeXForm

$$\Gamma (m+n i) \Gamma (m-n i)=n \pi \text{csch}(n \pi ) \prod _{j=1}^{m-1} (-1)^{2 j} (-n i+j) (n i+j)=n \pi \text{csch}(n \pi ) (1-i n)_{-1+m} (1+i n)_{-1+m}$$

 f[m_] := n π Csch[n π]*Product[(-1)^(2 j) (-n*I + j) (n*I + j ), {j, 1, m - 1}]
 f[5] // FullSimplify // Expand
 (*576 n π Csch[n π] + 820 n^3 π Csch[n π] + 273 n^5 π Csch[n π] + 30 n^7 π Csch[n π] + n^9 π Csch[n π] *)

 g[m_] := Gamma[m + n I] Gamma[m - n I]
 g[5] // FunctionExpand // Expand
 (*576 n π Csch[n π] + 820 n^3 π Csch[n π] + 273 n^5 π Csch[n π] + 30 n^7 π Csch[n π] + n^9 π Csch[n π] *)

Regards,MI

Posted 11 months ago

Hi MI, nice! Regards, OS

Reply to this discussion
Community posts can be styled and formatted using the Markdown syntax.
Reply Preview
Attachments
Remove
or Discard

Group Abstract Group Abstract