Message Boards Message Boards

GROUPS:

[GIF] J34 (Hopf projection of the 600-cell)

Posted 1 month ago
328 Views
|
1 Reply
|
3 Total Likes
|

Hopf projection of the 600-cell

J34

This shows a rotating 600-cell under the Hopf map. At least for the particular choice of coordinates I'm using, each of the 120 vertices of the 600-cell lies in the same complex line as 3 others, so the initial projection only has 30 vertices (in fact, it is the pentagonal orthobirotunda). With this particular rotation, two pairs split off before recombining.

Here's the Hopf map, along with the smoothstep function:

Hopf[{x_, y_, z_, w_}] := {x^2 + y^2 - z^2 - w^2, 2 y z - 2 w x, 2 w y + 2 x z};
smoothstep[x_] := 3 x^2 - 2 x^3;

And the vertices of the 600-cell, defined partially in terms of the vertices of the 8-cell and the 16-cell:

eightcellvertices = Normalize /@ {-1, -1, -1, -1}^# & /@ Tuples[{0, 1}, 4];
sixteencellvertices = Normalize /@ Flatten[Permutations[{-1, 0, 0, 0}]^# & /@ Range[1, 2], 1];
six00cellvertices = Join[sixteencellvertices, 1/2 eightcellvertices,
   Flatten[
    Outer[
     Permute, (1/2 {GoldenRatio, 1, 1/GoldenRatio, 0}*{-1, -1, -1, 0}^Append[#, 1] & /@ Tuples[{0, 1}, 3]), 
     GroupElements[AlternatingGroup[4]],
     1],
    1]
   ];

And, finally, here's the animation:

With[{pts = six00cellvertices, viewpoint = 2 {1, 0, 0}, 
  cols = RGBColor /@ {"#c3f1ff", "#f87d42", "#00136c"}},
 Manipulate[
  Graphics3D[
   Table[
    Sphere[Hopf[RotationMatrix[2 π/5 smoothstep[t], pts[[{5, 27}]]].pts[[i]]], .2],
    {i, 1, Length[pts]}],
   PlotRange -> 1.2, ViewAngle -> π/7, Boxed -> False, 
   ImageSize -> 540, ViewPoint -> viewpoint, 
   Background -> cols[[-1]],
   Lighting -> {{"Spot", cols[[1]], {{0, 0, -.75}, {0, 0, 1}}, π/2},
     {"Spot", cols[[2]], {{0, 0, .75}, {0, 0, -1}}, π/2},
     {"Ambient", cols[[-1]], viewpoint}}],
  {t, 0, 1}]
 ]

enter image description here - Congratulations! This post is now a Staff Pick as distinguished by a badge on your profile! Thanks, keep it coming!

Reply to this discussion
Community posts can be styled and formatted using the Markdown syntax.
Reply Preview
Attachments
Remove
or Discard

Group Abstract Group Abstract