Message Boards Message Boards

GROUPS:

[✓] Calculate and interpret Lim (x->0) ln(x!)/x ?

Posted 18 days ago
305 Views
|
4 Replies
|
10 Total Likes
|

Ploting this in geogebra gives an answer close to -0.5772, but I don't get why. Pls help me understand it. Also, it seems to be the same value for the derivative of ln(x!) when x->0, but I'm not sure about it. I came to this problem when trying to figure out what lim (x->0) x!^-x was, and I then found out that this is the same as lim (x->0) e^(ln(x!)/x), meaning that if i understand the "power" part, then I'll get the whole problem. I know it's another case where you have 0/0, but I still want to understand where does that answer from geogebra comes from. Plss help me!!

4 Replies

Expanding with series and then taking a limit is simpler to solve:

func = Series[Log[x!]/x, {x, 0, 5}] // Normal
(*-EulerGamma + (π^2 x)/12 + (π^4 x^3)/360 + (π^6 x^5)/5670 + 1/6 x^2 PolyGamma[2, 1] + 1/120 x^4 PolyGamma[4, 1] *)
Limit[func, x -> 0]
(* -EulerGamma *)
% // N
(* -0.577216 *)

Another way is use L'Hôpital's rule. We have [0/0] then:

D[Log[x!], x]/D[x, x] // FullSimplify
(* PolyGamma[0, 1 + x] *)
% /. x -> 0
(* -EulerGamma *)
In[2]:= Limit[Log[x!]/x, x -> 0]

Out[2]= -EulerGamma

In[3]:= N[%]

Out[3]= -0.577216

The other answers are correct, but it's just worth noting that Mathematica uses x! as an abbreviation for Gamma[x+1]. (When x is a nonnegative integer, then the value of Gamma[x+1] is that of Factorial[x].

To add to the response by @MurrayEisenberg, this can be used to explain why the limit is what it is. Without going through all details we'll just investigate the series for Gamma[1+z] at z=0. This amounts to looking at Gamma[z] and first derivative at z=1. Recall gamma definition as

Gamma[z] == Integrate[x^(z-1) Exp[-x], {x,0,Infinity}]

So Gamma[1] is given as

In[68]:= Integrate[x^(z - 1)*Exp[-x] /. z -> 1, {x, 0, Infinity}]

Out[68]= 1

For the first derivative, we differentiate under the integral sign (omitting details as to why this is valid).

In[69]:= Integrate[D[x^(z - 1)*Exp[-x], z] /. z -> 1, {x, 0, Infinity}]

Out[69]= -EulerGamma

The rest involving the log and dividing by z is straightforward using the series of the logarithm centered at 1.

Reply to this discussion
Community posts can be styled and formatted using the Markdown syntax.
Reply Preview
Attachments
Remove
or Discard

Group Abstract Group Abstract