Message Boards Message Boards

[GIF] A Legendrian Bloom

Posted 5 years ago

A Legendrian Bloom

This is another piece of artwork I did some time back. It came out of some of my investigations into orthogonal polynomials (which I might write about in future topics).

In particular, this animation features one subgroup of an large and intricate family of curves. This particular set can be described by the parametric equations

$$\begin{align*}x&=P_{\nu}(\cos t)\\ y&=P_{\nu}(\sin t) \end{align*}$$

where $P_{\nu}(z)$ is a Legendre polynomial, and $\nu$ is an odd integer.

To easily transition from one member to another, while also clearly depicting the fourfold symmetry of the curves, I used my rational variant of the "smoothstep" function,


to interpolate between curves, as well as to interpolate between $90^\circ$ rotations.

With[{n = 4, fg = ColorData["Legacy", "PermanentRedViolet"],
      bg = ColorData["Legacy", "DarkSlateGray"]},
     Manipulate[ParametricPlot[With[{h = (#^3/(1 - 3 # (1 - #))) & [Mod[u, 1]],
                                     m = 2 Floor[u] + 1, z = {Cos[t], Sin[t]}},
                                    RotationMatrix[? h/2].(
                                    (1 - h) LegendreP[m - 4 Floor[u - n]
                                                      UnitStep[u - n - 1], z] +
                                    h LegendreP[m + 2 - 4 Floor[u - n + 1] 
                                                UnitStep[u - n], z])],
                                {t, 0, 2 ?}, Axes -> None, Background -> bg,
                                PlotRange -> 9/8,
                                PlotStyle -> Directive[AbsoluteThickness[3], fg]],
                  {u, 0, 2 n}]]

The code is complicated by my desire to be able to transition forwards and backwards, as can be seen in the expressions I used for the orders of the Legendre polynomials.

n is a positive integer parameter you can increase if you wish to see more members of this group of curves.


enter image description here - Congratulations! This post is now a Staff Pick as distinguished by a badge on your profile! Thank you, keep it coming, and consider contributing your work to the The Notebook Archive!

POSTED BY: Moderation Team
Reply to this discussion
Community posts can be styled and formatted using the Markdown syntax.
Reply Preview
or Discard

Group Abstract Group Abstract