Hi Natash,

well, yes, of course, qua construction there are discontinuities:

Manipulate[
 Graphics[BezierCurve /@ cleanLinePoints[[;; n]], 
  PlotRange -> {{0, 550}, {0, 160}}, ImageSize -> Large], {n, 1, 
  Length[cleanLinePoints], 1}]

As described above my approach was to create a single line (using FindShortestTour) and to delete the jumps then. One can change the outcome of FindShortestTour by choosing a different order of the points which go into this function. You just have to play around a bit; I found using e.g.

pixelPos = SortBy[pixelPos, EuclideanDistance[{100, 100}, #] &];
order = Last[FindShortestTour[pixelPos]];

a somewhat better partitioning:

Try to be ceative!

Hi Henrik,

Thanks a lot. The dxf export works well. However, I see some discontinuities in the geometry created after importing dxf file.

I observe these discontinuities in the output of graphics = Graphics[BSplineCurve /@ cleanLinePoints] too.

I am also attaching the original image that I started with (here) for your kind reference. The image presented in the very beginning of this post is the centerline of a section of the original image.

Hi Natash,

I think you would rather need ImageMesh:

img = Binarize@
   Import["https://community.wolfram.com//c/portal/getImageAttachment?filename=ske3.png&userId=1555685"];

mesh = ImageMesh[img]

From this BoundaryMeshRegion line segments can be extracted (and viewed):

lines = MeshPrimitives[mesh, 1];

Manipulate[
 Graphics[lines[[;; n]], PlotRange -> {{0, 550}, {0, 160}}], {n, 1, Length[lines], 1}]

Obviously this structure is regarded as a two dimensional thing, and consequently the lines describe its boundary (and appear to run around twice ...). Furthermore some elements of the image border were detected.

But it should not be difficult to select the needed parts.

Does that help? Regards -- Henrik

Addendum/Edit:

Here comes a better solution: I start by cleaning up you original image by padding, then I calculate the positions of the white pixels. The problem now is that they are not ordered along a line. This can be improved by using FindShortestTour. Now the problem is that this gives a single line and there are necessarily jumps.

img1 = ImagePad[img, -1];
pixelPos = PixelValuePositions[img1, 1];
order = Last[FindShortestTour[pixelPos]];
Graphics[Line[pixelPos[[order]]]]

But with a little effort those long distances between two successive points can be detected and eliminated (... most likely there is a more elegant way of doing this):

longLineIndex = 
  Select[MapIndexed[{First[#2], EuclideanDistance @@ #1} &, 
     Partition[pixelPos[[order]], 2, 1]], Last[#] > 10 &][[All, 1]];
lineSequenceIndex = Partition[Join[{1}, longLineIndex, {Length[order]}], 2, 1];
lineSequenceIndex = Join[{lineSequenceIndex[[1]]}, {#1 + 1, #2} & @@@ lineSequenceIndex[[2 ;;]]];
cleanLinePoints = pixelPos[[order]][[Span @@ #]] & /@ lineSequenceIndex;
Graphics[BezierCurve /@ cleanLinePoints]

Sorry, I understand BeizierCurve command is used to fit a polynomial. But I am not sure how the degree of the polynomial is defined here. I'd like to fit a cubic spline. I'd also like to know how the splines can be exported for importing in CAD.