Thank you again Martiusz.

Do you know if there is a way to know in advance if a given DE cannot be solved analytically?

Does theory say anything about this question?

It can't be solved analyticaly,only numerically.

First we solve y1(t) and y2(t):

eqn2 = {y1'[t] == -24/10 y1[t] + B, 
   y2'[t] == -39/100 y2[t] + 24/140 y1[t]};
sol2 = DSolve[eqn2, {y1[t], y2[t]}, t] // Simplify
(*{{y1[t] -> (5 B)/12 + E^(-12 t/5) C[1], 
  y2[t] -> (50 B)/273 - 40/469 E^(-12 t/5) C[1] + 
    E^(-39 t/100) ((40 C[1])/469 + C[2])}}*)

Then we substitute to equation 3:

 eqn3 = y3'[t] == -7/10 Exp[-31/100 y3[t]] y3[t] + (y2[t] - 37/10) /. sol2
 Block[{Integrate}, DSolve[eqn3, y3[t], t] /. {Integrate -> Inactive[Integrate]}] 
(* After dozen minutes DSolve Can't Find Solution *)

Even after simplifying Equation y3(t), DSolve can't find a solution.

 Block[{Integrate}, 
  DSolve[{y3'[t] == c*E^(-39 t/100) - d* E^(-((31 y3[t])/100)) y3[t]}, 
    y3[t], t] /. {Integrate -> Inactive[Integrate]}] (* Input *)

Maple 2020 also can't find analytic solution

Solution by numerics:

eqn = {y1'[t] == -24/10 y1[t] + B, 
   y2'[t] == -39/100 y2[t] + 24/140 y1[t], 
   y3'[t] == -7/10 Exp[-31/100 y3[t]] y3[t] + (y2[t] - 37/10), 
   y1[0] == 0, y2[0] == 0, y3[0] == 0};
sol = ParametricNDSolveValue[eqn, {y1, y2, y3}, {t, 0, 1}, {B}]

Plot[Evaluate[Table[sol[B][[1]][t], {B, 1, 200, 1}]], {t, 0, 1}, 
 PlotRange -> All](*Solution for y1(t)*)

Plot[Evaluate[Table[sol[B][[2]][t], {B, 1, 200, 1}]], {t, 0, 1}, 
     PlotRange -> All](*Solution for y2(t)*)

Plot[Evaluate[Table[sol[B][[3]][t], {B, 1, 200, 1}]], {t, 0, 1}, 
     PlotRange -> All](*Solution for y3(t)*)