Message Boards Message Boards

Estimation of energy yield of 2020 Beirut port explosion

Probably most of you heard the sad news that there was a giant explosion in the port of Beirut today August 3rd 2020. Several videos were released on which we can do analysis. Note that the method I will use was also famously used by G.I. Taylor to find the energy of the Trinity nuclear bomb test, and he found the right amount to within 10%! We will not be so lucky as the video quality was relatively poor as compared to the high-speed imaging done back then.

I extracted several frames from one of the videos:

enter image description here

SetDirectory[NotebookDirectory[]];
v1 = Import["1.mp4"];
fra = VideoExtractFrames[v1, Interval[{11, 12}]]
fra = ImageRotate[#, Right] & /@ fra;

For each of the frames I identified the explosion by clicking 3 point on the circle:

 data={
{7,{{157.15625,365.20703125000006`},{233.83984375,379.76562500000006`},{272.015625,312.91015625000006`}}},
{8,{{318.16796874999994`,322.81640625000006`},{228.7890625,462.8515625},{103.61328125,393.38281250000006`}}},
{9,{{341.03515625000006`,311.34765625},{308.27734375,478.125},{93.86328125,420.34375}}},
{10,{{359.08984375,315.546875},{351.48828125,478.63671875000006`},{86.55078125,454.5078125}}},
{11,{{375.62109375,325.64453125},{330.05859375,535.3984375},{62.0390625,434.51171875}}},
{12,{{376.0390625,326.765625},{337.94140625,539.9257812499999},{46.4140625,462.55859375}}}
};

The first is the index of the frames, the last elements are points of the circle:

circs = CircleThrough /@ data[[;; 6, 2]];
r = circs[[All, 2]];

Here is the visualization:

Table[HighlightImage[fra[[data[[i, 1]]]], circs[[i]], "Boundary"], {i, Length[data]}]

enter image description here

Notice that I tracked the orange 'glow', not the shockwave or the smoke that was there partially before the main explosion (so on the conservative side and underestimating the energy release).

From Google earth I estimated the size of the face of the building on the left (a grain elevator) and found that every pixel corresponds to 0.59 m roughly (~22 meters corresponding to ~37 pixels).

cali = 0.5888486673789164`;
realr = r cali

The timestamps can be found from the video framerate.

Information[Import["video.mp4"]].

And so the timestamps are created and the dataset is created:

t = (Range[0, Length[realr] - 1]) 1/29.97;
tr = Transpose[{t, realr}]

Since the explosion started between two frames we include that in the fit (the t0):

fit = FindFit[
  tr, { a (x + t0)^0.4, 0 < t0 < 1/30}, {{a, 200}, {t0, 1/60}}, x]
realfit = a (x + t0)^0.4 /. fit
tzero = t0 /. fit
realfitshifted = a (x)^0.4 /. fit
prefactor = a /. fit

The fit can be found here and is based on dimensional analysis with the variable E (energy), r (radius of the explosion), t (time), and ρ (density). This also explains the exponent 0.4 used for fitting.

We plot the data and the fit:

Show[{ListPlot[Transpose[{t + tzero, realr}]], 
  Plot[realfitshifted, {x, 0, 0.2}]}, 
 PlotRange -> {{0, 0.2}, {0, 120}}, Frame -> True, 
 FrameLabel -> {"t", "r [m]"}]

enter image description here

Which is a pretty good fit.

We can now calculate the energy back from the explosion:

ClearAll[r, e, t, \[Rho]]
r == (e t^2/\[Rho])^(1/5)
Refine[DivideSides[%, t^(2/5)], t > 0]
%[[2]] == Quantity[prefactor, "Meters"/"Seconds"^(2/5)]
% /. \[Rho] -> Quantity[1, "Kilograms"/"Meters"^3]
energy = e /. Solve[%, e][[1]]

Yielding:

Quantity[4.2808721214488837`*^11, "Joules"]

and we can convert it to kiloton of TNT:

UnitConvert[energy, "KilotonsOfTNT"]

yielding:

Quantity[0.102315, "KilotonsOfTNT"]

This number is comparable to the 2015 Tianjin explosion (0.3 kilo tonnes of TNT).

POSTED BY: Sander Huisman
13 Replies

An extensive comparison between many videos finds roughly 200+- 80 tons of TNT. The analysis I showed is on the lower bound of their findings. As I said before, my analysis has some errors, and a factor of 3 can be accounted for, such that our results agree.

https://arxiv.org/pdf/2010.13537.pdf

POSTED BY: Sander Huisman
Posted 3 years ago

Hi All, very interesting analysis and discussion!

So bearing the following in mind:

  • This is just Ammonium Nitrate (not properly mixed ANFO) in an unknown condition.
  • The fire at the north end of Warehouse 12 is assumed to have initiated the explosion.
  • From photos the 1000KG bags of AN were stacked 2-3 high and haphazardly throughtout what appears to be a fairly spacious warehouse.
  • ANFO is notoriously difficult to initiate and without the a fuel component mixed througout the entire mass, and may not fully burn. This will probably decrease the yield considerably with straight Ammonium Nitrate.

My question is, looking at surface detonations from non-kinetic explosive devices it appears that the crater is far too large for the proposed yield.

I don't pretend to be able to check your calculations and the methodology looks thorough and any assumptions, reasonable.

Using this crater-size calculator, I changed the explosive type to ANFO and, the surface to Hard Soil/Dry Soft rock and set the yield to 2700 tonnes.

http://keith.aa.washington.edu/craterdata/scaling/index.htm

The tool produces a crater rim diameter of 60m whick explains the crater daimeter not the length of 120m.

The problems therefore appear to be:

  • An actual explosive was used in the calculation where in reality we had an oxidiser and some fuel.
  • The fuel and oxidiser were not uniformally mixed and therefore as above the yield cannot be 2700 metric tonnes.
  • Reducing the probable yield your upper end of 400 tonnes produces a rim diameter of 35m
  • Changing the surface material to 'dry soil' at a 400 tonne yield produced a 55m crater which is close the diameter but half the length of the actual crater.

With the Beirut crater length of 122m and the width half that at about 60m, we cannot model this even with the full yield using ANFO (correctly mixed, expected nitrogen levels, no contaminants).

Of course I have only changed several parameters and I don't know what that particular port quay was made from (mixture of concrete, bed rock, hardcore) with a surface load bearing limit somewhere in 30-50 tonnes per quare meter.

This leads me to thinking that some of the following may be valid:

  • The quay was very weak and a significantly larger crater could be created with a maximum 400 tonne yield but even if it was contructed with dry soil we can't get anywhere near 120m.
  • Explosive force distribution was abnormally biased downwards somehow? Could the 1000kg AN bags have been stacked by accident to create a shaped charge?
  • Some of the AN was stored underground but would place it potentially at or under sea level which doesn't make sense. However with dry sand with some of the explosives under the surface we can only get a crater size of 83m.

Of course there are quite a number of variables/unkowns here and even if the tool is reasonably accurate, it appears that the crater is too big for the yield.

One final thought around AN initiation, it appears that the risk of explostion increases with the level of confinement. Was the confinement level in this warehouse enough to get this amount of bang from nearly 2700 tonnes of hapahzardly stored AN?

Any thoughts guys?

POSTED BY: James Howel

Thanks for the clues! I have no idea on crater-explosion sizing though. Perhaps with the AN being relatively spread out (low height). I could imagine the models assume a 'point' explosion or a spherical-shaped explosion. So the crater might be wide, but not very deep and roughly a uniform depth.

Other ways of estimating the energy release could be sound-levels or (similarly) earth-quake measurements. Perhaps these combined measurements can give us several estimates.

POSTED BY: Sander Huisman
POSTED BY: Moderation Team
Posted 3 years ago

Thank you for studying an example, Dr. Huisman, This discussion will help in a better estimate.

I was looking over the variable, and I noticed you used the silo to help calculate the pixel to meter size.

From Google earth I estimated the size of the face of the building on the left (a grain elevator) and found that every pixel corresponds to 0.59 m roughly (~22 meters corresponding to ~37 pixels).

I looked up the silo, it is "Beirut Port Silos", https://www.facebook.com/silobeirut/.
https://www.world-grain.com/articles/14058-grain-silo-damaged-in-port-of-beirut-explosion

Exact measurements could be found, if it will help with accuracy. World Grain is a trade magazine, they may have the information on hand.

POSTED BY: Joe Kudrna
Posted 3 years ago

I looked at some more Sailor Hat images, revised the comparison estimate.

http://kauscience.k12.hi.us/Craters/Sailor_Hat.html

It has up to 85m (278.8ft) wide crater rim.

Looking at satellite images of the crater in Beirut, using the missing warehouse as an aid, my estimated crater size is 122m +/- 10m (400ft +/-30ft). Direct comparison cannot be made due to ground material composition but the Beirut crater does look larger.

I revise my earlier estimate downward, 400 to 1500 Tons of TNT equivalent.

POSTED BY: Joe Kudrna

I tried to do the analysis on the images for the Sailor Hat but there is too much blooming at the starting of the explosion, and the frame rate is pretty low for todays standards making the analysis very unreliable. Unfortunately I was unable to find high-speed videofootage/photos of the explosion like the trinity test:

enter image description here

I think your lower estimate would be my higher estimate so probably the truth is somewhere there. Thanks for checking.

POSTED BY: Sander Huisman
Posted 3 years ago

Dr. Huisman,

Your estimation of 300 tons of TNT is grossly below the evidence available, by a factor of 10. Your approach is viable, but something is off in the calculation.

Operation Sailor Hat was a series of 3 explosions carried out by the US Navy in the early 1950's. It was extremely well documentation, with multiple camera angels and post explosion analysis. The resulting damage and size of crater does not even come close to the tragedy in Beirut.
This test was 500 Tons of TNT (compared to your 300T-TNT estimate). https://en.wikipedia.org/wiki/Operation_Sailor_Hat

It is reported some 2750 tons of Ammonium Nitrate was in the warehouse, the Relative Effectiveness factor (RE factor) of AN is 0.42, so a crude approximation is 2750 x 0.42 = 1155 Tons of TNT.

Even then the crater size and blast radius suggest a TNT range of 2500 to 10,000 T-TNT. I speculate a larger quantity of AN was in that warehouse than known.

Your estimate to 2015 Tianjin explosion is suspect, because the warehouse company had poor record keeping on quantity and type of chemicals at location and possibility of political meddling might have adulterated already flawed official results.

Another example is the West, Texas explosion https://en.wikipedia.org/wiki/West_Fertilizer_Company_explosion Just under 300 tons of Ammonium products, RE of about 125T-TNT, crude estimate 40% of what you propose. Did not leave a crater.

Hope this helps fine tune your analysis.

POSTED BY: Joe Kudrna

Thanks for your reply.

This is an order-of-magnitude estimation factors of 3 off are normal. This method has been tested many times and simply works–independent of the stuff that explodes and works on the principles of fundamental physics.

As I said I was conservative in the radius determination, as you can see in the purple circles, you could draw them slightly bigger. (it goes with the 5th power so a small change goes a long way). Also the calibration can be off 5-10% which also goes with the 5th power. (though it could go both ways).

Moreover, the quoted amount of AN might not be correct and might not have exploded all at once. 1155 tonnes is the theoretical equivalent amount of TNT.

The explosion that happened in Tianjin seemed a lot larger than the one in Beirut which was estimated 300 tonnes of TNT equivalent.

Again, this is an estimate, the exact amount will never be known: some of the AN might not have burned, might have been contaminated. We can only give estimates after the fact based on videos or photos. I gave mine based on the explosion, i'm sure there are other ways like: based on Earthquake sensors, based on sound levels (dB), crater size, and so on. I'm happy for comparisons!

FYI: I also did the analysis on the original Trinity nuclear bomb test and found the numbers that Taylor also found. The code/principle seems to be correct.

POSTED BY: Sander Huisman
Posted 3 years ago

Fast reply! Thank you! (I added a little more after my first post).

I am not doubting your method, just the results.

Please check out videos on Sailor Hat and use the same method. It is the most perfectly analyzed large explosion known, not so large the researchers had to be located miles away (in fact, ships crew were below deck for detonation).

https://youtu.be/d_5TEkEhQGA

https://youtu.be/o3bQE2FYcKs

https://youtu.be/hkoBwFYitlU

Overhead pictures of the crater and damage. https://www.cnn.com/2020/08/05/world/satellite-images-beirut-explosion-before-after-trnd/index.html

POSTED BY: Joe Kudrna

Note that, the number of frames used can change the numbers a bit, this is the initial explosion, though it continues for a much longer time…

You would normally follow the invisible shockwave until it (roughly) reaches the speed of sound. Unfortunately this is not visible in this video, so the next possible thing is the fire I followed, and is definitely an under-estimation. Since the dependence is r^5, the energy release is most-certainly under-estimated.

POSTED BY: Sander Huisman

Dear Sander,

thank you for sharing this (as always) nice analysis - albeit done on a very, very sad incident! And I guess your approach is much more interesting and relevant than the result itself.

Best regards -- Henrik

POSTED BY: Henrik Schachner

Thanks Henrik! I think the idea of sharing is (at least) 4-fold: 1. how to do the image analysis and fitting in mathematica 2. introduction to dimensional analysis/physics 3. I've been in Beirut, and specifically to Martyr's square; very close to that harbor 4. In the current city i live there was a fireworks explosion some years ago, ruining a neighbourhood. Large parallels between the two, though Beirut's explosion is much larger.

POSTED BY: Sander Huisman
Reply to this discussion
Community posts can be styled and formatted using the Markdown syntax.
Reply Preview
Attachments
Remove
or Discard

Group Abstract Group Abstract