Combinations of 0 and 90 degrees will position the cylinder along the cube diagonals:

s = 1;
holeRadius = 0.18;
c = Cylinder[{{-s, s, s}, {s, -s, -s}}, holeRadius];


Manipulate[
    Graphics3D[{
        Rotate[         
             Rotate[
               Rotate[c, x Degree, {1, 0, 0}],
               y Degree, {0, 1, 0}
           ],
             z Degree, {0, 0, 1}
           ],
        Opacity@0.5,
        Cube[1.7]
    }, Boxed -> False],
    {x, {0, 90}}, {y, {0, 90}}, {z, {0, 90}},
    SaveDefinitions -> True
 ]

EDIT :

Sorry Brian, I misunderstood. Did not read your question close enough.

To rotate a Cylinder[{{0, 0, 0},{1, 0, 0}} so it points to a cube corner:

• Keep X angle at zero. A rotation around cylinder axis will not change orientation.
• Let Y angle be either + or - 35.2644. Which is plus or minus $\sin ^{-1}\left(\frac{1}{\sqrt{3}}\right)$

• Alternate Z angle between -135, -45, 45, 135

  Manipulate[
      Graphics3D[{
          Rotate[
               Rotate[
                 Cylinder[{{0, 0, 0}, {1, 0, 0}}, 0.1],
                 y Degree, {0, 1, 0}
             ],
               z Degree, {0, 0, 1}
             ],
          Opacity@0.5,
          Cube[]
      }, Boxed -> False, PlotRange -> 1.5],
      {y, {-35.2644, 35.2644}},
      {{z, 45}, {-135, -45, 45, 135}}
   ]