As to why the compiler didn't complain when I tried to execute the ParametricPlot3D code with the Lissajous3D definition missing, I have no idea :-)

Thought it might be helpful to comment on this. There isn't really a compiler in the common sense, and there is nothing directly analogous to static type checking. ParametricPlot3D was given two parameters and their ranges. It was given a "function" (an expression that looked like what you might think of as a function) that was being applied to those two parameters. That function (Lissajous3D), however, didn't have any rewrite/evaluation rules associated with it (because you hadn't evaluated the SetDelayed expression that "defined" the Lissajous3D "function"). So, ParametricPlot3D was just left with a bunch of stuff that it didn't know how to interpret as a plot, and so the resulting output just looked empty.

Here's an approach.

• Make the Lissajous curve wrap around a cylinder (I'm assuming this will give the 3D shape you want, but if you're wanting something else, like an over-under knot type pattern, then this won't work--but something else will :) )
• Use ParametricPlot3D
• Use two parameters in the plot to create a ribbon
• Use lighting or other styling to enhance the 3D effect.

Here's an example output:

Here is the code for the ParametricPlot3D:

ParametricPlot3D[
 Lissajous3D[1, 1, 3, Pi/3][t, s],
 {s, 0, .1}, {t, 0, 2 Pi},
 ViewPoint -> Front,
 ViewProjection -> "Orthographic",
 ColorFunction -> (White &),
 MeshStyle -> None,
 PlotPoints -> {20, 60},
 Lighting -> {{"Point", Blue, {0, -5, 0}}, {"Point", 
    Green, {3, -5, 0}}},
 Axes -> False]

You can see the options I've used, and hopefully that will get you started. The documentation for each option should help you figure out how to get your preferred appearance.

Here's the definition for the Lissajous3D function:

Lissajous3D[cx_, cy_, w_, d_][t_, s_] := {cx Sin[t w + d], cx Cos[t w + d], cy Sin[t] + Rescale[cx Cos[t w + d], {-1, 1}, {s, .5 s}]}

The x and z coordinates plot the 2d lissajous, and the y coordinate the front/back distance as if it was wrapping around a cylinder. This may not be the exact 3d shape you want, but hopefully it'll get you started. You can switch the coordinates to change the orientation.

Oh, sorry, I assumed too much.

If you're running Mathematica, you can just open a new notebook (File -> New -> Notebook). Copy the Lissajous3D code above, and paste it into the notebook. What you should have at that point is an Input cell. You'll see a bracket at the right side. With the cursor anywhere in that cell, tap Shift+Return. It won't produce any output, but it will have evaluated that code so that Lissajous3D is available to use like any other function. The cursor should now be below that cell. You can also just click anywhere in the whitespace below the cell to make sure. Now copy the whole ParametricPlot3D expression. Paste it into your Mathematica notebook. Again, with the cursor anywhere in this new cell, tap Shift+Return. This time it should output the plot, and it should look like the picture I pasted above. You can now tweak things in the ParametricPlot3D cell (don't need a new cell), and Shift+Return again.You can also tweak the Lissajous3D definition and Shift+Return that cell, and the next time you Shift+Return the ParametricPlot3D cell, it will use the updated definition.

I believe that it already does handle vertical and horizontal "frequencies". It just might be hard to see with examples you've tried. In the way I defined the lissajous function, the w argument is basically the ratio of the vertical and horizontal "frequencies". There are some subtleties here, because if it's not rational, then the curve doesn't "close", and if you don't extend your tmax far enough, you might not be getting enough "cycles" of the curve to see all of the "bumps". Also, the view angle can make it easier or harder to see.

For example, using my original definition, execute this:

ParametricPlot3D[
 Lissajous3D[1, 1, 4/3, Pi/3][t, s], {s, 0, .1}, {t, 0, 6 Pi}, 
 ViewPoint -> Front, ViewProjection -> "Orthographic", 
 ColorFunction -> (White &), MeshStyle -> None, 
 PlotPoints -> {20, 60}, 
 Lighting -> {{"Point", Blue, {0, -5, 0}}, {"Point", 
    Green, {3, -5, 0}}}, Axes -> False]

Then execute this:

ParametricPlot3D[
 Lissajous3D[1, 1, 3/4, Pi/2][t, s], {s, 0, .1}, {t, 0, 8 Pi}, 
 ViewPoint -> Front, ViewProjection -> "Orthographic", 
 ColorFunction -> (White &), MeshStyle -> None, 
 PlotPoints -> {20, 60}, 
 Lighting -> {{"Point", Blue, {0, -5, 0}}, {"Point", 
    Green, {3, -5, 0}}}, Axes -> False]

So, what you could do in your Manipulate is have a slider for vertical frequency and another for horizontal frequency (use new variable names for these--e.g. hf, vf-- and get rid of w), and then in the Lissajous3D expression, replace w with vf/hf.

Okay, my apologies. I figured it out. There was no output because I had not pasted the Lissajous function definition in. After I did that (ahead of the other code) and then pressed shift-ENTER, I got the plot.

Progress! lol.

Let me try to experiment with this and get back to you.

Thanks!