This is still confusing but I think you might want something like this.
(1) Define equations. Not solutions, but actual equations. I rationalize also, though that can be avoided sometimes.
eqns = {
ZCP == 1/(I*2*Pi*frequency*CP),
ZCin == 1/(I*2*Pi*frequency*Cin),
ZCL == 1/(I*2*Pi*frequency*CL),
ZP == 1/(1/RP + 1/ZCP),
Zin == 1/(1/Rin + 1/ZCin),
RPOL == 1/(1/RO + 1/(RL + ZCL)),
Iplus + IfbPlus == ILplus,
Iin + IpullUp == IfbPlus,
Iin + IfbMoins == Isig,
IfbMoins + Imoins == ILmoins,
Iplus == ((VCC2V5 + Av/2*Vd) - V1)/RO,
IfbPlus == (Vmoins - V1)/ZP,
ILplus == (V1 - VoutPlus)/RL,
IpullUp == (VCC2V5 - Vmoins)/RP,
Iin == Vd/Zin,
Isig == (Vsig - Vplus)/RP,
IfbMoins == (Vplus - V3)/ZP,
Imoins == ((VCC2V5 + Av/2*Vd) - V3)/RO,
ILmoins == (V3 - VoutMoins)/RL,
Vd == Vplus - Vmoins,
CurrPlus == (Av/2*Vd + VCM)/(RO),
CurrMoins == (Av/2*Vd + VCM)/(RO),
(Vmoins - V1)/RP + CurrPlus == V1/RPOL,
(Vplus - V3)/RP + CurrMoins == V3/RPO,
VoutPlus == V1*ZCL/(RL + ZCL),
VoutMoins == V3*ZCL/(RL + ZCL),
gain == (VoutPlus - VoutMoins)/(VoutPlus - Vmoins)
};
(2) Convert to polynomials. Not really needed but I do it anyway.
polys = Numerator[Together[Apply[Subtract, eqns, {1}]]]
(* {6250000 I + 7 \[Pi] ZCP, 500000000 I + \[Pi] ZCin,
2500000 I + 11 \[Pi] ZCL, -510 ZCP + 510 ZP +
ZCP ZP, -12000000 ZCin + 12000000 Zin + ZCin Zin, -511 +
2565 RPOL - 10 ZCL + 50 RPOL ZCL,
IfbPlus - ILplus + Iplus, -IfbPlus + Iin + IpullUp,
IfbMoins + Iin - Isig,
IfbMoins - ILmoins + Imoins, -25 + 2 Iplus + 10 V1 - 5 Vd,
V1 - Vmoins + IfbPlus ZP,
511 ILplus - 10 V1 + 10 VoutPlus, -5 + 1020 IpullUp + 2 Vmoins, -Vd +
Iin Zin, 510 Isig + Vplus - Vsig,
V3 - Vplus + IfbMoins ZP, -25 + 2 Imoins + 10 V3 - 5 Vd,
511 ILmoins - 10 V3 + 10 VoutMoins,
Vd + Vmoins - Vplus, -25 + 2 CurrPlus - 5 Vd, -25 + 2 CurrMoins -
5 Vd, 510 CurrPlus RPOL - 510 V1 - RPOL V1 + RPOL Vmoins,
510 CurrMoins RPO - 510 V3 - RPO V3 + RPO Vplus,
511 VoutPlus - 10 V1 ZCL + 10 VoutPlus ZCL,
511 VoutMoins - 10 V3 ZCL + 10 VoutMoins ZCL,
gain Vmoins - VoutMoins + VoutPlus - gain VoutPlus} *)
Now we solve just for the gain.
soln =
NSolveValues[polys, gain, Complement[Variables[polys], {gain}]]
(* Out[100]= {3.07079*10^-6 + 3.36972*10^-9 I} *)