I am grateful to Eric and Rohit for showing me new ways to do this. My original project involved creating the bitmap using pixelmath, which can do with a couple of lines of code, and then importing it into Mathematica to add the labels. This thread has become a useful resource for making bitmaps in Mathematica and for combining them with plotting and graphics functions, and I will refer to it in the future. As I think Henrik noticed, the two rotations in colTxt[] just canceled each other. I fixed that.

To overlay numbers using Eric's answer use Epilog.

epilog = {Yellow, MapIndexed[Text[#1, {First@#2, 10} - 1/2] &, Range@10]};
MatrixPlot[colorGrid, Epilog -> epilog]

You can add a column of rotated text to the epilog for the vertical numbers.

Gary, glad to help!

I don’t understand why PlotRange should affect the positioning, ...

If you do not specify PlotRange then values are used to make the graphics just large enough to show (most of) the objects. You can check:

gr0 = Graphics[{row1, col1, originPt}, PlotRangePadding -> None, ImageSize -> iDims];
AbsoluteOptions[gr0, PlotRange]
(*   Out:    {PlotRange\[Rule]{{-460.8,460.8},{0.,972.8}}}   *)

This represents not even a square, but a rectangle!

Gary,

besides Eric's nice solution, here is another approach:

I guess the basic problem of your code is that you define in a clean way a row of numbers - and then, less cleanly, simply rotate that to get the column of numbers. So I just add a function colText[] where just the numbers are rotated:

(*GLOBALS*)
iDims = ImageDimensions@bitmap;

(*grid parameters*)
imgWd = 1024;(*width and height of image*)n = 10.;(*number rows or columns*)
 wd = imgWd/10.;(*width of row or column*)
rowStart = imgWd - wd/2.;
colStart = -imgWd/2. + wd/2.;

(*text values*)
txtSz = 16;
color = Yellow;
face = Bold;

(*FUNCTION*)
rowTxt[row_] := 
  Table[Text[
    Style[ToString[m + 1], {txtSz, color, face}], {colStart + m*wd, (rowStart - row*wd)}], {m, Range[0, n - 1]}];
colTxt[row_] := 
  Table[Text[
    Style[Rotate[ToString[m + 1], -Pi/2], {txtSz, color, 
      face}], {colStart, (rowStart - +m*wd)}], {m, Range[1, n - 1]}];
(*OBJECTS*)
rect = Rectangle[{{0, 0}, {100, 100}}];(*does not display*)
row1 = rowTxt[0];(*should be in top row*)
col1 = colTxt[0];(*should be in column 1?*)
originPt = {Yellow, PointSize[.03], Point[{0, 0}]};
(*displays at bottom*)

(* definition of graphics: *)
gr = Graphics[{row1, col1, originPt}, PlotRangePadding -> None, 
   PlotRange -> {{-imgWd/2., imgWd/2.}, {1, imgWd}}, 
   ImageSize -> iDims];
ImageCompose[bitmap, gr]

I would probably work with just plain images. You could create a function that creates the "cells" for each number and then assembles those into an overlay. So, for example:

MakeTextCellOverlay[dims_, styles_, text_] := 
 ColorReplace[ImageCrop[RemoveBackground[Rasterize[Style[text, styles]]], dims], White]

You can pass your desired styles and dimensions along with the text. You've already specified the styles you want. You can calculate the dimensions however you want, but I'll assume that each cell is scaled by a factor of 10 in each dimension:

cellDimensions = ImageDimensions[bitmap]/10

Now we compute the individual cells:

overlayCells = 
 MakeTextCellOverlay[cellDimensions, {16, RGBColor[1, 1, 0], Bold}, #] & /@ Range[10]

Use these to make row and column:

row = ImageAssemble[{overlayCells}];
column = ImageRotate[row, -Pi/2]

Now compose everything:

ImageCompose[ImageCompose[bitmap, column, Scaled[{.05, .5}]], row, Scaled[{.5, .05}]]

Now, I don't know what you want to do about the "collision" in the lower left corner, but hopefully this has given you enough to play with. Tweak it until you get what you want.