Thank you again for your very clear and helpful explanation. You should write a book or a manual for people trying to learn how to use Mathematica.

Let's start from this point:

BPr1= NormalizeDateTime/@BProws

Let's get your plot first, and then later I'll explain some of the issues with your code.

DateListPlot[BPr1[[All, {1, 3}]]]

DateListPlot can work with a couple different forms, but we have date-value pairs in our data, so we just need extract them and pass them to DateListPlot. This is the bit that extracts the pairs:

BPr1[[All, {1, 3}]]

You'll want to become familiar with the various forms for Part (double brackets are just syntactic sugar for Part). BPr1 is 2-dimensional, so we can use two index specifications separated by a comma. So, BPr1[[1,3]] would be the third element in the first row, for example. But Part can also take a list for an index specification, and it will fetch according to each index in the list at that level. And then there is the special form of All, which is like a list that includes every index at that level. So, BPr1[[All, {1, 3}]] is saying "fetch from all rows the 1st and 3rd elements".

Okay, now let's critique your code.

• TableForm

  bp = Import["/Users/ericr/WolframWorkspace/MmaCommunity/BP_readings_mathematica_test.xlsx", {"Data", 1}, HeaderLines -> 4] // TableForm
  

  Use TableForm for presentation, but don't pollute your data with it. What you have in bp at this point is a TableForm expression with your data inside of it. This will make all future processing of your data difficult, as you'll need to work around the TableForm head. Now, you can't see an explicit TableForm in your output, so what am I talking about? You should become familiar with FullForm. Everything in Mathematica is an expression of a very specific syntactic form. We have syntactic sugar on the input side so we don't have to deal with that standard from all of the time. We have presentation functionality in the notebook interface to make the output look nice. But under the covers, every expression is actually in a very specific form, and it's rather verbose. To force the UI to show you this form, use FullForm. So, try this

  FullForm[bp]
  

  You should see the TableForm at the head of this expression. The standard thing to do if you want to see your data in TableForm is to first assign the variable and then display the variable. So, something like this:

  bp = <...the import goes here...>;
  TableForm[bp]
  

• Mutation doesn't occur automatically

  Let's look at this:

  BPr1/."  --"->Missing[]/.""->Missing[]
  

  Quick side note: you can use a list with ReplaceAll to apply multiple replacement rules:

  BPr1 /. {"  --" -> Missing[], "" -> Missing[]}
  

  Now, this will evaluate fine and produce an output, but you haven't saved that result to a variable, so it's difficult to use it later. I might be reading too much into your code, but it looks to me like you're assuming that BPr1 will now have the "cleaned" data in it, but it won't. BPr1 didn't change at all. You can mutate BPr1 directly or use a different variable:

  BPr1 = BPr1 /. {"  --" -> Missing[], "" -> Missing[]}
  (* Or *)
  BPr1Clean = BPr1 /. {"  --" -> Missing[], "" -> Missing[]}
  

  I tend to use the latter, as it's often useful to have a sort of record of what I did. I sometimes need to start over from a particular spot.

• Pay attention to the forms used in the documentation

  Now let's look at this:

  DateListPlot[{datetime},{sysBP}]
  

  That doesn't really match any of the patterns in the documentation. datetime and sysBP are already lists, but you've wrapped them in another layer of List. DateListPlot doesn't know what to do with that.

  Similarly with:

  Transpose[{{datetime},{sysBP}}]
  

  What you probably wanted here was

  Transpose[{datetime, sysBP}]
  

  And this would have worked just fine:

  DateListPlot[Transpose[{datetime, sysBP}]]
  

Thanks for the suggestions, It worked . Is NormalizeDateTime a built in function? (I searched but it didnt come up) or a user defined function? (I was told to use lower case for user defined functions which is why I ask).

How did it know to join the first two columns with the date join command (is that default?). I was looking for a Part command and it didn't seem to be needed. And what does "rest" do...

And is it easy enough to change GMT to EST with a command? How would one do that?

and yes, Excel can be difficult or a mess to deal with . Unfortunately, it is commonly used for data collection so would be nice if Mathematica could anticipate the idiosyncrasies of Excel just because its so common. I will try saving as a cvs file and see if that works as well.,

thanks so much for your help, Roger

It looks to me like those times (second column) are actually dates. Maybe in Excel choosing to format something as a time also causes the internal representation to become a date. I don't know what magic Excel is doing under the covers. I would either figure out how to force those dates into actual times, if that's possible, or just avoid importing the xlsx file directly. It might be safer to export from Excel into csv, and then import the csv.

But, you could also just fix the data once you have it in Mathematica.

rawBP = Import[pathToFile, {"Data", 1}, HeaderLines -> 1];
BProws = DeleteCases[rawBP, {"" ...}];

We now have non-empty rows. Let's define a function to combine the dates and "times":

NormalizeDateTime[{date_, time_, rest___}] := 
  {DateObject[Join[DateValue[date, {"Year", "Month", "Day"}], DateValue[time, {"Hour", "Minute", "Second"}]]], rest}

And apply it to the data:

NormalizeDateTime /@ BProws