The following works fine for me, although with a different answer:

Clear[x];
p = Pi/(2 Sqrt[2]);
dgl = \[Theta]''[x] - p^2 Sin[2 \[Theta][x]] == 0;
sol = NDSolve[{dgl, \[Theta][0] == Pi/2, \[Theta]'[0] == 
    0}, \[Theta], {x, 0, 1}]
entry = \[Theta][1] /. sol[[1]]

I cannot reproduce the error you get, but it is similar to what we happens when the independent variable of a differential equation is given a value before NDSolve is called:

x = 0;
NDSolve[{f'[x] == 1, f[0] == 0}, f, {x, 0, 1}]

The variables f, x are not automatically protected from outside interference. However, in your case there must be something else going on.

In this case it is no pendulum equation, but an equilibrium condition for a rod in a crooked channel with an asymmetric cross-section. There is no oscillation going on.

You cannot use \[Theta]_entry as a variable name, it is a pattern. I would do it this way:

sol[t0_] := NDSolveValue[
   {\[Theta]''[x] - (\[Pi]/(2 Sqrt[2]))^2 Sin[2 \[Theta][x]] == 0,
    \[Theta][0] == t0, \[Theta]'[0] == 0}, \[Theta], {x, 0, 1}];
Table[{t0, sol[t0][1]},
 {t0, 0, 2 Pi, 0.125 Pi}]