Have you tried

Hold[Plot[Sin[x], {x, 0, Pi}]]

Sure! But it would really help to know what you want to do with these plot expressions in your function. Each plot function could have different options or different argument patterns, so if you're inspecting the expression inside your function, you probably can't avoid some special-casing.

Anyway, the function MyPlotWrapper that I showed you has "knowledge" of all the parts of the plot expression, so you can just assemble the pieces together when you're ready to execute the plot. Or, you can just name the whole argument pattern, and avoid having to reassemble the pieces.

SetAttributes[MyPlotWrapper, HoldFirst];
MyPlotWrapper[p_[fns_, range_, options___]] :=
 Column[
   {"head: " <> ToString[p], 
    "function(s): " <> ToString[fns], 
    "range: " <> ToString[range], 
    "options: " <> ToString[{options}], 
    Row[{"the plot", p[fns, range, options]}]}]

Or

SetAttributes[MyPlotWrapper, HoldFirst];
MyPlotWrapper[expr : p_[fns_, range_, options___]] :=
  Column[
    {"head: " <> ToString[p], 
     "function(s): " <> ToString[fns], 
     "range: " <> ToString[range], 
     "options: " <> ToString[{options}], 
     Row[{"the plot", expr}]}]

I assume you're trying to distinguish between Plot and Plot3D. One way is to simply overload the wrapper to have two separate definitions.

MyPlotWrapper[Plot[fns_List, range_, options___]] := ...
MyPlotWrapper[Plot3D[fns_List, range_, options___]] := ...

Another way would be to use a pattern for the head.

MyPlotWrapper[p_[fns_List, range_, options___]] :=
 Switch[
  p,
  Plot, "a 2d plot",
  Plot3D, "a 3d plot",
  _, "this is not a plot!"]

There are many ways, but without knowing what you're trying to do, it's difficult to give complete and precise guidance. Here is just one example that will hopefully get you started.

SetAttributes[MyPlotWrapper, HoldFirst];
MyPlotWrapper[Plot[fns_List, range_, options___]] := 
 ToString[
  StringForm[
    "I will plot `` over `` with `` options", 
    Head /@ fns, Rest@range, Length[{options}]]]

Demonstration:

MyPlotWrapper[Plot[{Sin[x], Cos[x]}, {x, 0, Pi}, PlotLegends -> "Expressions"]]
(* "I will plot {Sin, Cos} over {0, Pi} with 1 options" *)