Your region reg is a circle, not a surface. Your vector n is normal to the circle, but not to the surface. What you are calculating is not a surface integral.

I would do the surface integral like this:

surf = ImplicitRegion[{x^2 + y^2 == 2*z, z <= 2}, {x, y, z}];
n = Normalize[D[x^2 + y^2 - 2*z, {{x, y, z}}]] /. Abs -> Identity;
Integrate[
 Dot[Curl[{3*y, -x*z, y*z^2}, {x, y, z}], n], {x, y, z} \[Element] 
  surf]

The sign of the final result depends on the choice of the orientation of the surface, i.e., on the choice between n and -n.

That's a lot more complicated, because I think Mathematica has no built-in routine for this kind of integrals (yet?). The cleanest way is to parameterize the circle with trigonometric functions, but I don't know a way to make Mathematica find such a parameterization for you. Mathematica can find partial parameterizations as algebraic functions with Solve

Solve[{x^2 + y^2 == 2 z, z == 2}, {y, z}]

Once you have the parameterizations you can compute the tangent vector and integrate, but you have to check that the orientation of the partial parameterizations are consistent with each other.

You can avoid the parameterization altogether, and work all the time implicitly:

v1 = D[x^2 + y^2 - 2 z, {{x, y, z}}];
v2 = D[z - 2, {{x, y, z}}];
tangentVersor = 
  Simplify[
   Normalize[{a, b, c} /. 
      First@Solve[{v1.{a, b, c} == 0, v2.{a, b, c} == 0}, {a, b, 
         c}]] /. Abs -> Identity, a > 0 && y > 0];
reg = ImplicitRegion[{x^2 + y^2 == 2 z, z == 2}, {x, y, z}]
Integrate[{3 y, -x z, y z^2}.tangentVersor, {x, y, z} \[Element] reg]

but you still have to check that the tangent versor has consistent direction.

A is a Vector field S is a surface C is a circle intersection on the surface S

It use stroke's theorem to compute the flux, so the answer is -20*pi, But how can I use Mathematica to compute?