Adding a quaternion Log function that works also when first nonzero element of vector part is negative.

Input and output quaternions are represented as lists.

quatLog[q : {q0_, q1_, q2_, q3_}] := With[
  {qV = {q1, q2, q3}},
  If[And[VectorQ[q, NumericQ], N@Norm[q] == 1],
    Flatten@{0, Normalize[qV] ArcCos[q0]},
    Simplify@Flatten@{Log@Norm[q], Normalize[qV] ArcCos[q0/Norm[q]]}
  ]
]

Came across another issue with the Quaternions package. Taking the logarithm of a quaternion and then raising e to the log should return the original quaternion. But that is not always the case.

These works as expected:

Needs@"Quaternions`"

Exp@Log@Quaternion[1., 2., 3., 4.]
Exp@Log@Quaternion[1., 2., -3., 4.]

Quaternion[1., 2., 3., 4.]
Quaternion[1., 2., -3., 4.]

But not these:

Exp@Log@Quaternion[1., -2., 3., 4.]
Exp@Log@Quaternion[1., 0., -3., 4.]

Quaternion[1., 2., -3., -4.]
Quaternion[1., 0., 3., -4.]

The problem occurs when the first nonzero element of the vector part (= last 3 elements) is negative.

The failure is due to a faulty definition of Sign[] for Quaternion[] objects. To fix this, you'll need to edit the package yourself. Find the line

Quaternion /:
    Sign[a:Quaternion[__?ScalarQ]]:= a / Abs[a]

in the package, and replace it with

Quaternion /:
    Sign[a:Quaternion[__?ScalarQ]]:= With[{d = Abs[a]}, If[d != 0, a / d, 0]]