Message Boards Message Boards

GROUPS:

[GIF] Catecoid (Catenoid/Helicoid associate family)

Posted 2 years ago
2508 Views
|
1 Reply
|
3 Total Likes
|

Catenoid/Helicoid associate family

Catecoid

In the spirit of Self-Conjugate, Family Resemblance, and Gridded, here's the associate family of the catenoid and helicoid (I took a crack at this once before, with Locally Isometric).

The code uses a trick suggested by Jens Noeckel in this Stack Exchange thread to make the mesh lines have variable colors. I didn't really bother optimizing, so it's kind of slow, but here's the code which generated the GIF:

catecoid = With[{
    cols = RGBColor /@ {"#2BCDC1", "#F66095", "#393E46"},
    n = 80},
   ParallelTable[Module[{offset},
       ParametricPlot3D[{Cos[t] Sinh[v] Sin[u] + Sin[t] Cosh[v] Cos[u], 
          -Cos[t] Sinh[v] Cos[u] + Sin[t] Cosh[v] Sin[u], u Cos[t] + v Sin[t]},
        {u, -π, π}, {v, -2, 2},
        ViewPoint -> Front, Boxed -> False, Axes -> None, 
        PlotRange -> 4, ViewAngle -> π/5, 
        MeshFunctions -> 
         Map[Function[{x, y, z}, z - offset] /. offset -> # &, Range[8/(2 n), 8, 8/n]], Mesh -> {{-4}}, PlotPoints -> 50, 
        MeshStyle -> 
         Table[Directive[Thickness[.003], Blend[cols[[;; -2]], Rescale[i, {n/4, 3 n/4}]]], {i, 1, n}], 
        PlotStyle -> None, Background -> cols[[-1]], ImageSize -> 540]],
      {t, 0., 2 π - #, #}] &[2 π/100]
   ];

Export[NotebookDirectory[] <> "catecoid.gif", catecoid, "DisplayDurations" -> {1/24}]

enter image description here - another post of yours has been selected for the Staff Picks group, congratulations !

We are happy to see you at the top of the "Featured Contributor" board. Thank you for your wonderful contributions, and please keep them coming!

Reply to this discussion
Community posts can be styled and formatted using the Markdown syntax.
Reply Preview
Attachments
Remove
or Discard

Group Abstract Group Abstract