Problem

Find the equation of the plane through the point $(3, -2, 8)$ parallel to the plane $z = x + y$. Use Mathematica to sketch the planes and the line between the original plane and the new translated plane.

Solution

You should look at the guide for "Plane Geometry" - or in the help section of Mathematica or online: Plane Geometry. You also can look at the guide for Geometric Computation and specifically Properties and Measures.

I Solved your problem doing the following:

(* I picked three points on the plane z = x + y by putting in 0 or 1 for x and y *)
    pl = InfinitePlane[{{0, 0, 0}, {1, 0, 1}, {0, 1, 1}}];
    Graphics3D[pl]
mypt = {3, -2, 8}

(* find the point on the plane nearest mypt *)
pt = RegionNearest[pl, mypt]

(* although not needed, calculate the distance *)
dist = SignedRegionDistance[pl, mypt]

(* calculate a translation to move the plane *)
dir = mypt - pt

(* translate the plane in the distance in that direction *)
pl2 = TransformedRegion[pl, TranslationTransform[dir]]

(* create a line to see if we did it correctly *)
myln = Line[{pt, mypt}]

(* Now graph the old plane, the new plane and the line to see if it really works out *)
Graphics3D[{pl, myln, pl2}]

(* Equation for your new plane *)
RegionMember[pl2, {x, y, z}][[2]]