Message Boards Message Boards

[GIF] To Infinity ((2,1) torus knot)

(2,1) torus knot

To Infinity

This one is very simple: just a $(2,1)$-torus knot (which of course is topologically an unknot) viewed from straight on (rather than above, which is the more common viewpoint for torus knots). I quite like the blending of colors on the spheres, which was achieved by placing a total of 16 point source lights on a grid in the scene.

The downside of using so many lights in Lighting is that it really slows things down. Just based on quick-and-dirty experimentation, it seems like everything slows to a crawl when you get above about 10 distinct light sources.

That being said, here's code using only 8 point lights (plus one ambient light source) that looks almost the same as the animation and is fast enough to Manipulate reasonably. If you really want to recreate the animation, use d=0.82 rather than d=0.8 and use {j, 0, n, α} rather than {j, 2, n, α}.

Stereo3D[{x1_, y1_, x2_, y2_}] := {x1/(1 - y2), y1/(1 - y2), x2/(1 - y2)};

pqtorus[t_, φ_, p_, q_] := 1/Sqrt[2] {E^(p I (t + φ/p)), E^(q I t)};

With[{viewpoint = {2, 0, 0}, d = .8, n = 3, α = 1, m = 30,
  cols = RGBColor /@ {"#08D9D6", "#FF2E63", "#252A34"}},
 Manipulate[
  Graphics3D[
   {Sphere[#, .1] & /@ 
     Table[Stereo3D[Flatten[ReIm /@ pqtorus[t + φ, 0, 2, 1]]], {t, 0., 2 Pi, 2 Pi/m}]},
   PlotRange -> 3, ViewPoint -> viewpoint, ViewVertical -> {1, 0, 0}, 
   ViewAngle -> Pi/9, ViewCenter -> {.38, .5, .5}, Boxed -> False, 
   Background -> cols[[-1]], ImageSize -> 540,
   Lighting -> 
    Append[Flatten[
      Table[{"Point", Darker[Blend[Reverse@cols[[;; 2]], i/n], d], {3/2 (j - n/2), 3/2 (i - n/2), 0}}, 
         {i, 0, n, α}, {j, 2, n, α}], 1], 
        {"Ambient", cols[[-1]], viewpoint}]],
  {φ, 0., 2 Pi/m}]
 ]
2 Replies

Very interesting. Actually this 4-manifold (i.e. time variant 3-manifold) describes the static electron 2-manifold which is a twisted 1/2 spin photon.

A normal photon is actually a circle loop or else called, Standard Unknot.

enter image description here -- you have earned Featured Contributor Badge enter image description here Your exceptional post has been selected for our editorial column Staff Picks http://wolfr.am/StaffPicks and Your Profile is now distinguished by a Featured Contributor Badge and is displayed on the Featured Contributor Board. Thank you!

POSTED BY: Moderation Team
Reply to this discussion
Community posts can be styled and formatted using the Markdown syntax.
Reply Preview
Attachments
Remove
or Discard

Group Abstract Group Abstract