Norm is a way to estimate the sum of the residuals and Quiet stops the beeping that I was getting from warnings. Here is an example:

dat = {d1, d2, d3};
model = {m1, m2, m3};
resid = model - dat;
Norm@resid // InputForm (* \
Sqrt[Abs[-d1+m1]^2+Abs[-d2+m2]^2+Abs[-d3+m3]^2] *)

Roberto,

I think that your integral expression leads to difficult numerics. If you take the semicolon away, the output is conditional expression about a page long. If you evaluate numerically, you often can get warnings and imaginary components in the results.

You may want use Mathematica's Manipulate functionality to manually explore the data. Here is an example where you try to manually minimize the Norm function by manipulating the sliders as shown below:

phi[n_, a_, a2_][x_] := 
 n*(x (1 - x))^(a - 1/2) (1 + a2*GegenbauerC[2, a, (2 x - 1)])
fitxm[n_, a_, a2_][m_] := 
 Quiet@NIntegrate[phi[n, a, a2][x] (2*x - 1)^m, {x, 0, 1}]
xd[n_, a_, a2_] := fitxm[n, a, a2][#] & /@ Range[2, 50, 2]
normf[n_, a_, a2_] := Quiet@Norm@(xd[n, a, a2] - xmpardata)
Manipulate[global = {n, a, a2}; 
 ListPlot[{xmpardata, xd[n, a, a2]}, PlotLabel -> normf[n, a, a2], 
  PlotLegends -> {"Data", "Fit"}], {{n, 1.1}, 0.9, 1.2}, {{a, 0.58}, 
  0.45, 0.7}, {{a2, -0.44}, -0.5, -0.3}]
Dynamic@global

If your end goal is to perform the numerical integration, then you are probably making it much more difficult than it needs to be. If you plot the data with ListLogLogPlot, it is very linear suggesting LinearModelFit is in order.

data = {{2, 0.243098}, {4, 0.127303}, {6, 0.0834994}, {8, 
    0.0609518}, {10, 0.0473757}, {12, 0.0384113}, {14, 
    0.0320716}, {16, 0.027407}, {18, 0.0237647}, {20, 0.020894}, {22, 
    0.0185901}, {24, 0.0167308}, {26, 0.0151393}, {28, 0.013839}, {30,
     0.0127182}, {32, 0.0117066}, {34, 0.0108577}, {36, 
    0.0101237}, {38, 0.00948312}, {40, 0.00887854}, {42, 
    0.00834716}, {44, 0.00788257}, {46, 0.00746653}, {48, 
    0.00705183}, {50, 0.00669624}};
fit = LinearModelFit[Log@data, x, x]
phipar[x_] := Exp@Normal@fit;
fit["ParameterTable"]
Plot[Normal@fit, {x, 0.5, 4}, Axes -> False, Frame -> True, 
 Epilog -> {PointSize@.02, Point@Log@data}]
f[m_] := NIntegrate[(2*x - 1)^m (phipar[x]), {x, 0, 1}]
f[2] (* 0.130834 *)

With your current formulation, $aRL\alpha par$ must be even integers to avoid complex numbers since $x\geq 2$ making the argument negative.

$$\phi_{par}=N_{par}\left ( x\left ( 1-x \right ) \right )^{aRL\alpha par}....$$

While I think that datasets should explicitly have the response value and all predictors, it seems that most if not all of the Wolfram Language fitting functions take a dataset with just the response values in a single list and then assumes that the single predictor variable is from the list Range[Length[data]].

However, the OP's data would need to be Flatten'ed to get it in the form of a single list that those functions would accept.

Also having the term in the form of (x(1-x))^k and all positive response values suggests that maybe the x values are between zero and one rather than between 2 and 50.

Sorry, I've never used Mathematica before, so I do not know many things, I have a dat with the first 25 even Gegenbauer polynomials of second order for fit, I fix the table

xmdatapar = 
  ReadList["/home/roberto/F?ica/Pesquisa/<X^m>/kaon/lib/pares/xm_\
pares.dat", {Number, Number}];
xmpardata = 
 Table[{xmdatapar[[i, 1]], xmdatapar[[i, 2]]}, {i, 1, 
   Length[xmdatapar]}]

{{2, 0.243098}, {4, 0.127303}, {6, 0.0834994}, {8, 0.0609518}, {10, 
  0.0473757}, {12, 0.0384113}, {14, 0.0320716}, {16, 0.027407}, {18, 
  0.0237647}, {20, 0.020894}, {22, 0.0185901}, {24, 0.0167308}, {26, 
  0.0151393}, {28, 0.013839}, {30, 0.0127182}, {32, 0.0117066}, {34, 
  0.0108577}, {36, 0.0101237}, {38, 0.00948312}, {40, 
  0.00887854}, {42, 0.00834716}, {44, 0.00788257}, {46, 
  0.00746653}, {48, 0.00705183}, {50, 0.00669624}}

where the first value is the first term sum of even numbers 2,4,6,8,10...50 and the second value is a x moments,

i need to fit this function

 In[86]:= \[Phi]par := 
      Npar*(x (1 - x))^
       aRL\[Alpha]par (1 + \[Alpha]2RLpar*
          GegenbauerC[2, \[Alpha]RLpar, (2 x - 1)]);

where phi is related to this integral

F[m_] := NIntegrate[(2*x - 1)^m (\[Phi]par[x] ), {x, 
   0, 1}]

where m = 2,4,6,8,10,12... so how I can do this ??

In[89]:= fitpar = 
 FindFit[xmpardata, {\[Phi]par}, {Npar, 
   aRL\[Alpha]par, \[Alpha]2RLpar}, {x}]

During evaluation of In[89]:= FindFit::nrlnum: The function value {-0.243098-2. (1. +1. (-1. \[Alpha]RLpar+18. \[Alpha]RLpar Plus[<<2>>])),-0.127303-12. (1. +1. (-1. \[Alpha]RLpar+98. \[Alpha]RLpar Plus[<<2>>])),<<22>>,-0.00669624-2450. (1. +1. (-1. \[Alpha]RLpar+19602. \[Alpha]RLpar Plus[<<2>>]))} is not a list of real numbers with dimensions {25} at {Npar,aRL\[Alpha]par,\[Alpha]2RLpar} = {1.,1.,1.}.

During evaluation of In[89]:= FindFit::nrlnum: The function value {-0.243098-2. (1. +1. (-1. \[Alpha]RLpar+18. \[Alpha]RLpar Plus[<<2>>])),-0.127303-12. (1. +1. (-1. \[Alpha]RLpar+98. \[Alpha]RLpar Plus[<<2>>])),<<22>>,-0.00669624-2450. (1. +1. (-1. \[Alpha]RLpar+19602. \[Alpha]RLpar Plus[<<2>>]))} is not a list of real numbers with dimensions {25} at {Npar,aRL\[Alpha]par,\[Alpha]2RLpar} = {1.,1.,1.}.

Out[89]= FindFit[{{2, 0.243098}, {4, 0.127303}, {6, 0.0834994}, {8, 
   0.0609518}, {10, 0.0473757}, {12, 0.0384113}, {14, 0.0320716}, {16,
    0.027407}, {18, 0.0237647}, {20, 0.020894}, {22, 0.0185901}, {24, 
   0.0167308}, {26, 0.0151393}, {28, 0.013839}, {30, 0.0127182}, {32, 
   0.0117066}, {34, 0.0108577}, {36, 0.0101237}, {38, 
   0.00948312}, {40, 0.00887854}, {42, 0.00834716}, {44, 
   0.00788257}, {46, 0.00746653}, {48, 0.00705183}, {50, 
   0.00669624}}, {Npar ((1 - x) x)^
   aRL\[Alpha]par (1 + \[Alpha]2RLpar (-\[Alpha]RLpar + 
        2 (-1 + 2 x)^2 \[Alpha]RLpar (1 + \[Alpha]RLpar)))}, {Npar, 
  aRL\[Alpha]par, \[Alpha]2RLpar}, {x}]

Thanks.