Thanks Hans!...I fixed the code and it is now ready for the use with halogens (+H) from hydrogen to iodine with all the options of the function.

This short note ought to be of interest.

-- from my first post in this thread, at the bottom ;)

OK. The notebook I attached gives 74 halomethanes as well. That looks fine.

the article I linked to corroborates this.

Sorry. Which article?

I attach an article of Markus van Almsick, Helmut Hoenig and me and a zip-file prepared by Markus (I never used it, because (and that is an outing) I simply don't know how to do it).

Sorry, attaching a zip-file is not supported. If you like to get it just send me an email:

h.dolhaine@gmx.de

Perhaps that zip-file is helpful for dealing with substiutional isomers.

Attachments:

j_chem_inf_sci.pdf

Hello Hans, as J.M. pointed out, in the beginning I assumed that there was steriometry between e.g.: HFHF/HHFF..., but I was wrong, because halomethanes are tetrahedric in space and not planar, I'm already working on a code update to fix this.

This is a great post.

However I am somewhat lost: how many different halomethanes are there?

I attach a notebook which was written long time ago to cope with the number of substitutional isomers. Note that in the real world only the pure rotation-group of a molecule accounts for the number of possible isomers.

In the notebook the pure rotation-group T of a tetrahedron is generated by two generating elements, a C2 and a C3-axis.

Then an isomer counting algorithm is applied and a list of isomers with different numbers of substituents is given. The halomethanes are found at the very end (nsubs = 4 ). It says that for the halomethane of structural type a2b2 there is exactly one isomer, but the cofactor says that there are 6 combinations of halogens possible, giving a total of 6 halomethanes of this structural type.

The structural type abcd yields 2 isomers (2 enantiomers), but only one combination (cofactor) of 4 different halogens.

Attachments:

halomethanes.nb

The "irregularity" you might be thinking of is because the C-X bond lengths (generally) increase with increasing atomic number of the ligand, so e.g. a C-I bond is considerably longer than a C-F bond. Nevertheless, VSEPR will still ensure the sp³ hybridized carbon atom has a tetrahedral configuration. From my limited experience with trying MoleculePlot3D[] on Wolfram Cloud, it at least knows this aspect of VSEPR.

I did account for enantiomers in the ugly solution I posted; that's why I split the count into "chiral" and "achiral" sets.

The analysis of the "square planar" configuration you initially considered does apply for e.g. metal complexes; in there, you can have cis-trans isomerism, and thus two isomers of a substance where two of each ligand is attached to the center.

Looking at your list rp, it seems you double-counted a few of the halomethanes; e.g. difluoromethane is counted twice.

Here's a rather inefficient count:

halInit = DeleteDuplicates[Sort /@ Tuples[{"H", "F", "Cl", "Br", "I"}, {4}]];
chiral = Select[halInit, Signature[#] != 0 &];
(* use achiral = Complement[halInit, chiral] instead
   if you don't care about scrambling *)
achiral = Select[halInit, Signature[#] == 0 &];

Length[achiral] + 2 Length[chiral]
   75

(I am certain there is a neat combinatorial trick that would eliminate the need to throw out dupes, but sadly, my already limited mathematical and programming skills escape me currently.)

^{(added during afternoon tea time)}

It turns out that if one recalls that the group of symmetries of the tetrahedron correspond to the degree 4 alternating group, you get a pretty quick filtering scheme:

halInit =
DeleteDuplicatesBy[Tuples[{"H", "F", "Cl", "Br", "I"}, {4}], 
                   Sort /@ Union[PermutationReplace[#, AlternatingGroup[4]]] &];
chiral = Select[halInit, Signature[#] != 0 &];
achiral = Complement[halInit, chiral];

(Certainly, there ought to be a nicer way to leverage the permutation group functionality of Mathematica, but my knowledge of group theory has gone rusty.)

With that, here's some ugly code written during a quick lunch break, like the one I am having right now:

makeCX4SMILESAchiral[a_?VectorQ] :=
ToString[StringForm["`1`C(`2`)(`3`)`4`", ##] & @@ (a /. "H" -> "[H]")]

makeCX4SMILESChiral[a_?VectorQ] :=
ToString[StringForm["`1`[C@](`2`)(`3`)`4`",
                    Sequence @@ ((a /. "H" -> "[H]")[[#]])]] & /@
                    {{1, 2, 3, 4}, {1, 4, 3, 2}}

mols = Molecule /@ Join[makeCX4SMILESAchiral /@ achiral,
                        Flatten[makeCX4SMILESChiral /@ chiral]];

Length[mols] == Length[Union[mols, SameTest -> MoleculeEquivalentQ]]
   True

after which you can just map over MoleculePlot(3D)[]* if you actually want the pictures.

^{* - Users of older Mathematica versions can use something like MoleculeViewer[] instead.}

This short note ought to be of interest.