That is not quite a project for a novice. However, here is a way:

Manipulate[
 StreamPlot[{x (1 - y), y (-\[Lambda] + x)},
  {x, 0, 2}, {y, 0, 2}],
 {{\[Lambda], 1}, 0, 2}]

@Gianluca Gorni : Nice - simple, but very intuitive!

I guess for the full solution one needs ParametricNDSolve and friends:

ClearAll["Global`*"]
(* define the Lotka model: *)
x0 = 2; y0 = 1.5;
tRange = {t, 0, 30};
deq = {x'[t] == x[t] (1 - y[t]), y'[t] == y[t] (-\[Lambda] + x[t]), x[0] == x0, y[0] == y0};
(* solve it: *)
lotka = ParametricNDSolveValue[deq, {x[t], y[t]}, tRange, {\[Lambda]}];
(* show the solution: *)
Manipulate[ParametricPlot[lotka[\[Lambda]], Evaluate@tRange, PlotRange -> {{0, 11}, {0, 4.3}}, PerformanceGoal -> "Quality", 
  ImageSize -> Large, GridLines -> {{x0}, {y0}}, Epilog -> {Dashed, Red, 
    InfiniteLine[{{\[Lambda], 0}, {\[Lambda], 1}}]}], {\[Lambda], .3, 5}]

Manipulate[
 Plot[Evaluate@lotka[\[Lambda]], tRange, Filling -> Bottom, 
  PlotRange -> {0, Automatic}, ImageSize -> Large], {\[Lambda], 0, 5}]