This type integrals can be solved only by numerics:

w = 1;
g = 1; 
NIntegrate[ExpIntegralEi[-s]*Exp[(-s*w^2)/(1 + 2*s*g^2)]/Sqrt[1 + 2*s*g^2], {s, 
     0, Infinity}]
(*-0.669167 *)

No hope for a closed-form solution by existing special function.

Using:$\sum _{j=0}^{\infty } \frac{x^j}{j!}=\exp (x)$

we can find solution by infinite Series:

 func = Integrate[(-((s w^2)/(1 + 2 g^2 s)))^j/j!* ExpIntegralEi[-s]/
    Sqrt[1 + 2 g^2 s] // PowerExpand, {s, 0, Infinity}, 
  Assumptions -> {j >= 0, w > 0, g > 0}] // FullSimplify // Expand

(*((-1)^j 2^(1 - j) g^(-2 - 2 j) j Sqrt[\[Pi]] w^(2 j) Gamma[j])/(
 j! Gamma[1/2 + j]) + ((-1)^(1 + j) 2^-j EulerGamma g^(-2 - 2 j)
   j Sqrt[\[Pi]] w^(2 j) Gamma[j])/(
 j! Gamma[1/2 + j]) + ((-1)^(1 + j) 2^-j g^(-2 - 2 j) j Sqrt[\[Pi]]
   w^(2 j) Gamma[j] HarmonicNumber[j])/(
 j! Gamma[1/2 + j]) + ((-1)^(1 + j) 2^(1/2 - j) g^(-1 - 2 j)
   Sqrt[\[Pi]] w^(2 j)
   HypergeometricPFQ[{-(1/2), 1/2 + j}, {1/2, 1/2}, 1/(2 g^2)])/
 j! - ((-(1/2))^j g^(-4 - 2 j) Sqrt[\[Pi]] w^(2 j)
   Gamma[2 + j] HypergeometricPFQ[{1, 1, 2 + j}, {2, 2, 5/2}, 1/(
   2 g^2)])/(
 3 j! Gamma[1/2 + j]) + ((-1)^(1 + j) 2^-j g^(-2 - 2 j) j Sqrt[\[Pi]]
   w^(2 j) Gamma[j] Log[2])/(
 j! Gamma[1/2 + j]) + ((-1)^j 2^(1 - j) g^(-2 - 2 j) j Sqrt[\[Pi]] w^(
  2 j) Gamma[j] Log[g])/(j! Gamma[1/2 + j])*)

func2 = Sum[func[[1 ;; 3]], {j, 0, Infinity}] + 
   Sum[func[[6 ;; 7]], {j, 0, Infinity}] + 
   Sum[func[[4 ;; 5]], {j, 0, Infinity}] // Simplify
(*Sum[((-1)^(1 + j)*2^(1/2 - j)*g^(-1 - 2*j)*Sqrt[Pi]*w^(2*j)*HypergeometricPFQ[{-1/2, 1/2 + j}, {1/2, 1/2}, 1/(2*g^2)])/j! - 
   ((-1/2)^j*g^(-4 - 2*j)*Sqrt[Pi]*w^(2*j)*Gamma[2 + j]*HypergeometricPFQ[{1, 1, 2 + j}, {2, 2, 5/2}, 1/(2*g^2)])/(3*j!*Gamma[1/2 + j]), {j, 0, Infinity}] - 
 (((2*E^(w^2/(2*g^2))*g - Sqrt[2*Pi]*w*Erfi[w/(Sqrt[2]*g)])*(-2 + EulerGamma + Log[2] - 2*Log[g]))/E^(w^2/(2*g^2)) + 
   2*g*Derivative[1, 0, 0][Hypergeometric1F1][1, 1/2, -1/2*w^2/g^2])/(2*g^3)*)

Then:

 F[g_, w_, M_] := 
  Sum[(((-1)^(1 + j) 2^(1/2 - j) g^(-1 - 2 j) Sqrt[\[Pi]] w^(2 j)
         HypergeometricPFQ[{-(1/2), 1/2 + j}, {1/2, 1/2}, 1/(2 g^2)])/
       j! - ((-(1/2))^j g^(-4 - 2 j) Sqrt[\[Pi]] w^(2 j)
         Gamma[2 + j] HypergeometricPFQ[{1, 1, 2 + j}, {2, 2, 5/2}, 1/(
         2 g^2)])/(3 j! Gamma[1/2 + j])), {j, 0, M}] - (
    E^(-(w^2/(
       2 g^2))) (2 E^(w^2/(2 g^2)) g - 
        Sqrt[2 \[Pi]] w Erfi[w/(Sqrt[2] g)]) (-2 + EulerGamma + 
        Log[2] - 2 Log[g]) + 
     2 g Derivative[1, 0, 0][Hypergeometric1F1][1, 
       1/2, -1/2*w^2/g^2])/(2 g^3) // N

F[1, 1, 100](*Where M is should be a infinity in this case M=100*)
(*-0.669167 + 0. I*)

Looks like answer is the same.