In the article I mentioned "Generation of view dependent models using free form deformation the authors use 2D information to make 3D objects. But in my case, I needed all 3 dimensional info (the code for and a circle, and a triangle and a square) They use 2 views to generate a complete 3D object...and their method is way more universal (and complicated) Glad you enjoyed my contribution.

Glad you enjoyed my contribution and it gave you new inspiration! So did your beautiful website: CIRCLE BASE SOLIDS. Please go ahead and use whatever you need! Inspired by your colourfully shaded 3D prints, I adapted my "sqriancle" function and changed the square to a parabola and made it a "pariancle" (parabola/triangle/ circle)

ParametricPlot3D[{{r Cos[\[Phi]], r Sin[\[Phi]], 0.}, {r Cos[\[Phi]], 
   r Sin[\[Phi]], -2 (-1 + r^2 Cos[\[Phi]]^2 + 
      Abs[r Sin[\[Phi]]] Sqrt[1 - r^2 Cos[\[Phi]]^2])}}, {\[Phi], 0, 
  2 \[Pi]}, {r, 0, 1}, PlotPoints -> 25, 
 PlotStyle -> Lighter[Yellow, .05], MeshFunctions -> {#1 &, #2 &}, 
 Mesh -> {16, 16}, MeshStyle -> AbsoluteThickness[1], 
 PlotRange -> {{-1, 1}, {-1, 1}, {0, 2}}, Boxed -> False, 
 Axes -> False]

To add some color, I changed it to slices:

slice[{y1_, y2_}, col_] := 
 First@ParametricPlot3D[{{r Cos[\[Phi]], r Sin[\[Phi]], 
     0.}, {r Cos[\[Phi]], 
     r Sin[\[Phi]], -2 (-1 + r^2 Cos[\[Phi]]^2 + 
        Abs[r Sin[\[Phi]]] Sqrt[1 - r^2 Cos[\[Phi]]^2])}}, {\[Phi], 0,
     2 \[Pi]}, {r, 0, 1}, Mesh -> None, PlotPoints -> 50, 
   PlotStyle -> col, 
   RegionFunction -> Function[{x, y, z}, y1 <= y <= y2], 
   BoundaryStyle -> AbsoluteThickness[1], 
   PlotRange -> {{-1, 1}, {-1, 1}, {0, 2}}, Boxed -> False, 
   Axes -> False]

bounds = Partition[Range[-1, 1, .125], 2, 1];

pariancle = 
 Show[MapThread[Graphics3D[slice[#1, #2]] &, {bounds, colors}], 
  Boxed -> False, Lighting -> "ThreePoint"]

Grid[{Style[#, Bold] & /@ {"default", "Side", "Top", "Front"}, 
  Show[pariancle, PlotRange -> {{-1, 1}, {-1, 1}, {0, 2}}, 
     Boxed -> False, Axes -> False, ViewPoint -> #, 
     ViewAngle -> 1.5 \[Degree], 
     Lighting -> "ThreePoint"] & /@ {16 {1.3, -2.4, 2}, {50, 1, 
     0}, {0, 0, 50}, {0, -50, 1}}}, Spacings -> 0]

Wish I had a 3D printer now. Have fun!

Hi, Erik! The "Sqriancle" is now available as a free STL file download. It is posted at Cults3D: https://cults3d.com/en/3d-model/various/sqriancle. More photos are on that web page too. Thanks again for the inspiration for this project!