Have you tried MovingMap and similar functions that work with temporal data? I have never used them, but from a first reading they sound similar to what you are after.

That plot is wrong. It is not the plot of pwPAMV. If you ask ?pwPAMV you will see that its definition contains the replacement t->ut, which is treated badly by Plot, and correctly by NIntegrate.

There is one more problem with your code: Count does not play well with symbolic manipulation:

Clear[f];
f[t_] := Count[{1, 2, 3}, x_ /; (t - 2) \[LessSlantEqual] x < t];
f[3]
f[t] /. t -> 3

This means that your functions FC1, FC2 and those built with these, must be calculated only with numerical values of t. If you feed them a symbolic value, they give nonsensical results. Here is a reworking of your code that corrects for the problem:

pwPA[t_] = 
  Piecewise[
   Partition[
    Riffle[vf, 
     Table[
      vti[[i]] \[LessSlantEqual] t < vti[[i + 1]], {i, 1, ni + 1}]], 
    2]];

pwtemp1[t_] = 
  Piecewise[{{pwPA[t - Vscc], 
     Vscc \[LessSlantEqual] t < 2 Vscc}, {pwPA[t - f Vscc], 
     2 Vscc \[LessSlantEqual] t < m}}];

FC1[t_?NumericQ] := 
  Count[vti, x_ /; (t - Vscc) \[LessSlantEqual] x < t];
FC2[t_?NumericQ] := 
  Count[vti, x_ /; (t - f Vscc) \[LessSlantEqual] x < t];
pwtemp2[t_?NumericQ] := 
  Piecewise[{{PSA^FC1[t], 
     Vscc \[LessSlantEqual] t < 2 Vscc}, {PSA^FC2[t], 
     2 Vscc \[LessSlantEqual] t < m}}];

pwPAMV[ut_?NumericQ] := pwtemp1[ut] pwtemp2[ut];

pl1 = Plot[pwtemp1[tt], {tt, 0, m}, PlotRange -> Full, Filling -> Axis]
NIntegrate[pwtemp1[tt], {tt, 0, m}]/m
pl2 = Plot[pwPAMV[tt], {tt, 0, m}, PlotRange -> Full, 
  Filling -> Axis]
NIntegrate[pwPAMV[tt], {tt, 0, m}]/m

In a previous post I suggested using DiracDelta instead of Count. That would allow symbolic manipulation.

This seems to work:

FC1alternative[t_] = 
 Integrate[Sum[DiracDelta[t - k], {k, vti}], {t, t - Vscc, t}, 
    Assumptions -> Element[t, Reals]] /. HeavisideTheta -> UnitStep //
   PiecewiseExpand
Plot[FC1[t], {t, -1, 12}, PlotRange -> {-.1, 3.1}]
Plot[FC1alternative[t], {t, -1, 12}, PlotRange -> {-.1, 3.1}, 
 Exclusions -> None]

You forgot to divide by m. Anyway, your "functions" are awfully convoluted in their definition and Plot gets them in the wrong evaluation order. Insert Evaluate and see what happens:

Plot[pwPAMV[tt], {tt, 0, m}, PlotRange -> Full, Filling -> Axis]
Plot[Evaluate[pwPAMV[tt]], {tt, 0, m}, PlotRange -> Full, 
 Filling -> Axis]

Try this simpler example, where it is easier to understand what happens:

f := Sin[x] /. x -> Pi/2 - x;
Plot[f, {x, 0, 2 Pi}]
Plot[Evaluate[f], {x, 0, 2 Pi}]

Here I get different integrals

Vscc = 1.5; f = 0.6;
\[Tau]1 = Vscc; \[Tau]2 = f Vscc; \[Tau]3m = f Vscc; m = 10;
PAI = 0.04819277; \[Lambda] = 0.03150354; PSA = 0.025; ni = 
 IntegerPart[(m - \[Tau]1 - \[Tau]2)/\[Tau]3m] + 2;
vti = Flatten[
   Append[Append[{0, \[Tau]1, \[Tau]1 + \[Tau]2}, 
     Table[\[Tau]1 + \[Tau]2 + (i - 2) \[Tau]3m, {i, 3, ni}]], m]];
F[t_] = 1 - Exp[-\[Lambda] t];
vf = {F[t] + PAI};
Do[vf = Append[vf, 
    F[t - vti[[i]]] + PSA (vf[[i - 1]] /. t -> vti[[i]])], {i, 2, 
   ni + 1}];
pwPA = Piecewise[
   Partition[
    Riffle[vf, 
     Table[vti[[i]] \[LessSlantEqual] t < vti[[i + 1]], {i, 1, 
       ni + 1}]], 2]];

pwtemp1 = 
  Piecewise[{{pwPA /. t -> (t - Vscc), 
     Vscc \[LessSlantEqual] t < 2 Vscc}, {pwPA /. t -> (t - f Vscc), 
     2 Vscc \[LessSlantEqual] t < m}}];

FC1[t_] := Count[vti, x_ /; (t - Vscc) \[LessSlantEqual] x < t];
FC2[t_] := Count[vti, x_ /; (t - f Vscc) \[LessSlantEqual] x < t];
pwtemp2[t_] := 
  Piecewise[{{PSA^FC1[t], 
     Vscc \[LessSlantEqual] t < 2 Vscc}, {PSA^FC2[t], 
     2 Vscc \[LessSlantEqual] t < m}}];

pwPAMV[ut_] := (pwtemp1 /. t -> ut) pwtemp2[ut];

    pl1 = Plot[(pwtemp1 /. t -> tt), {tt, 0, m}, PlotRange -> Full, Filling -> Axis]
    NIntegrate[pwtemp1, {t, 0, m}]
    pl2 = Plot[pwPAMV[tt], {tt, 0, m}, PlotRange -> Full, Filling -> Axis]
    NIntegrate[pwPAMV[tt], {tt, 0, m}]/m

Hello Andre Luiz,

in my opinion the main problem is the absolute complex structure of your code.

Did you consider to use something like this?

Plot[
 {
  Piecewise[
   {
    {0, x < 3},
    {1 + 1.5 x, 3 <= x < 4},
    {SawtoothWave[{0, 1.3}, .9 x], 4 <= x < 9},
    {0, x < 9}
    }
   ]
  },
 {x, 0, 10},
 PlotStyle -> Red,
 PlotRange -> {0, 8},
 Filling -> Axis
 ]

Your integrands seem to be equal

pwPAMV[t] - pwtemp1 // Simplify