3) There is a Correlation Function (http://reference.wolfram.com/language/ref/Correlation.html). You'll need to get your data into the correct "shape". You can extract different properties from the TimeSeries data you get from FinancialData. For example, you can do this:

finDataDJI = FinancialData["DJI", {{2021, 1, 8}, {2021, 12, 31}, "Day"}]

finDataDJI["Values"]

You can do that for each series and then apply Correlation. However, you'll need to carefully align the data.

There may be other correlation functions that you prefer. Check them out here http://reference.wolfram.com/language/guide/DescriptiveStatistics.html.

Hi David,

Here is one way

date = "1/1/2021";
dji = FinancialData["^DJI", date];
eth = FinancialData["ETH/USD", date];

(* Extract date/value pairs *)
djiData = dji["DatePath"];
ethData = eth["DatePath"];

(* Identify dates common to both *)
commonDates = Intersection[djiData[[All, 1]], ethData[[All, 1]]];

(* Filter to common dates *)
djiFiltered = Select[djiData, MemberQ[commonDates, First@#] &];
ethFiltered = Select[ethData, MemberQ[commonDates, First@#] &];

(* Use the resource function CombinePlots to generate a 2 axis plot *)
ResourceFunction["CombinePlots"][
 DateListPlot[djiFiltered,
  PlotStyle -> ColorData[97][1],
  PlotLegends -> LineLegend[{ColorData[97][1]}, {"DJI"}]],
 DateListPlot[ethFiltered,
  PlotStyle -> ColorData[97][2],
  PlotLegends -> LineLegend[{ColorData[97][2]}, {"ETH"}]],
 "AxesSides" -> "TwoY"]

(* Compute correlation *)
Correlation[djiFiltered[[All, 2]], ethFiltered[[All, 2]]]
(* 0.814973 *)

Hi David,

Once you get proficient with the Wolfram Language you will find that it takes very little effort to manipulate date and generate simple visualizations for exploratory data analysis. It took me ~ 5 min to write that code. To generalize it a bit we can define a function that takes two symbols, a start date and end date, and generates a plot of the price with the correlation as the plot label.

ClearAll@compareFinancialData;
compareFinancialData[symbol1_String, symbol2_String, startDate_, endDate_] := Module[
  {data1, data2, commonDates, filtered1, filtered2},

  data1 = FinancialData[symbol1, {startDate, endDate}]["DatePath"];
  data2 = FinancialData[symbol2, {startDate, endDate}]["DatePath"];

  commonDates = Intersection[data1[[All, 1]], data2[[All, 1]]];

  filtered1 = Select[data1, MemberQ[commonDates, First@#] &];
  filtered2 = Select[data2, MemberQ[commonDates, First@#] &];

  ResourceFunction["CombinePlots"][
   DateListPlot[filtered1,
    PlotStyle -> ColorData[97][1],
    PlotLegends -> LineLegend[{ColorData[97][2]}, {symbol1}],
    PlotLabel -> 
     "Correlation: " <> 
      ToString@Round[Correlation[filtered1[[All, 2]], filtered2[[All, 2]]], .001],
    ImageSize -> 500],
   DateListPlot[filtered2,
    PlotStyle -> ColorData[97][2],
    PlotLegends -> LineLegend[{ColorData[97][2]}, {symbol2}],
    FrameStyle -> ColorData[97][2]],
   "AxesSides" -> "TwoY"]
  ]

To reproduce the previous result

compareFinancialData["^DJI", "ETH/USD", "2021-01-01", Today]

To compare a set of symbols

symbols = {"^DJI", "ETH/USD", "BTC/USD", "XRP/USD"};

Subsets[symbols, {2}] // 
 Map[compareFinancialData[First@#, Last@#, "2021-01-01", Today] &] //
 Partition[#, UpTo[2]] & // 
 Grid[#, Frame -> All, Spacings -> {1, 1}] &

The date string format "1/1/2021" is ambiguous, is it M/D/Y or D/M/Y? Use an unambiguous format such as "YYYY-MM-DD".

FinancialData has data on a small set of cryptocurrencies. If you are interested in cryptocurrency data analysis, take a look at this resource function by @Anton Antonov. I believe he has submitted it for inclusion in the function repository, but it is not yet available there.

1) Use the PlotLegends option